"The Magpie Takes the Train" by Brian Rushton

The story genre is "Espionage". The story headline is "Set in the world of Alias 'The Magpie'. A short tale". The story description is "This is a heist game set on a train." The story creation year is 2020. The release number is 9.

Use no scoring, the serial comma, and American dialect.

Include Basic Screen Effects by Emily Short.

Include Glulx Text Effects by Emily Short.

Factchecking is an action out of world. Understand "facts" as factchecking.

Release along with cover art ("A parrot grasping a gem, a shadowy hand grabbing the parrot.").

Carry out factchecking:
	repeat with current running through things:
		say "Description of [current]: [description of current]";
		say "[line break]";

Volume 1 - Material Things

Book 1 - Places

Part 1 - Station

Chapter 1 - Basics

Section 1 - Room Description

Station is a room. "This part of the station has been roped off for members of Hogg's entourage and guests only. [first time]Cornelia Hogg's [attendant] is here, waiting for latecomers. [only]The entrance to the train is to the east."

The trainexterior is scenery in Station. The printed name of trainexterior is "railroad car". Understand "railroad" or "Hogg's" or "car" or "train" or "observation" as the trainexterior. The description of the trainexterior is "Hogg's luxury car. Expensive, yes. Tasteful? Debatable."

Instead of touching the trainexterior:
	say "[The attendant] says, 'Please do not handle the train.";
	
Instead of pushing the trainexterior:
	say "[The attendant] says, 'Please do not handle the train.";

Instead of pulling the trainexterior:
	say "[The attendant] says, 'Please do not handle the train.";

Instead of kissing the trainexterior:
	say "[The attendant] says, 'Please do not handle the train.";

The ropes are scenery in Station. The description of the ropes is "These luxurious ropes keep the common man away from Hogg's car." Understand "rope"as the ropes.

Instead of taking the ropes:
	say "They are quite heavy."

Instead of swinging the ropes:
	say "You push the ropes and they swing back and forth."

The  entrance is scenery in Station. The description of entrance is "Your entrance onto the train. You've used it every time you've attempted this heist."

Instead of opening the entrance:
	say "It's already open."
	
Instead of closing the entrance:
	say "Why? You're trying to get on, after all.";
	
Instead of entering the entrance:
	try going east;

Before going east from Station:
	if Greetings is TargetGiven:
		say "The attendant goes before you. You walk through an ornate but unimportant hallway before emerging into the Observation Car. You can feel the train starting to move.";
		now the player is in Observation Car;
		now the attendant is in Observation Car;
		deliver Introductions;
		deliver Hello;
		deliver Familiar instead;	
	otherwise:
		say "[The attendant] does not move. She's waiting for you to introduce yourself." instead;

[The hallway is never accessed]

Hallway is east of Station.

The description of Hallway is "You [one of]hop on the train, entering [or]are in [stopping]a long hallway with a single, presumptuously ornate door to the north and a more subdued door to the south."

The presumptuously ornate door is north of Hallway and south of Observation Car. The presumptuously ornate door is a closed, locked, openable lockable door. The presumptuously ornate door is scenery. The description of the presumptuously ornate door is "The door is wrought in the Art Deco style and has ridges upon ridges of shining metal." Understand "presumptuous" as the presumptuously ornate door. Understand "north door" as the presumptuously ornate door.

The subdued door is south of Hallway and north of Limbo. The subdued door is a closed, locked, openable, lockable door. The description of the subdued door is "A servant entrance, most likely to the kitchens. You've learned that it is unimportant through your past attempts at the rose, which included baking an exceedingly large cake and providing an inordinate amount of wine for the head chef." Understand "south door" as the subdued door.

The subdued door is scenery.

A quip is a kind of thing.
Greetings is a quip.

Report looking for the first time:
	say "You hand [the attendant] your card with a flourish.

She holds the card close to her face, adjusting her spectacles. '[Alias in row CurrentAlias of the Table of Aliases]?' she asks, using your current alias.";
	deliver Greetings;

Following is an action applying to one thing. Understand "follow [someone]" as following.

Carry out following:
	if the player is in Station:
		if the noun is the attendant:
			try going east;
		otherwise:
			say "The only person you need to follow is [the attendant]!";
	otherwise:
		if the noun is the server:
			say "You're not leaving until you have the Rose!";
		otherwise:
			say "[The noun] isn't going anywhere, so you do the same."

Part 2 - Observation Car

Chapter 1 - Basics

Section 1 - Room Description

Observation Car is a room. 

The description of Observation Car is "You [one of]step into [Cornelia Hogg]'s[or]are in Cornelia Hogg's[stopping] sumptuous private observation car. The room is [if the shades are not drawn]illuminated by the sunlit windows[otherwise]dim now with the shades drawn,[end if] and the floor is covered in vivid chartreuse carpeting. A door to the south leads to freedom, once you're finished here.[first time]

Cornelia Hogg is here as always, furiously scribbling. Horus, [the parrot] you have come to despise, is on his perch at her side. [The Viscount], [one of]a frequent passenger who is clearly wearing a disguise,[or]still wearing his ridiculous disguise,[stopping] is perusing a magazine.[only][first time]

Ah, there it is! The Gavinchian Rose, jewel of jewels, sitting on Hogg's lapel. It's so close, you could reach out and take it. Is it just that simple?[only]";

Section 2 - Scenery

Does the player mean doing something with scenery:
	it is unlikely;

The floor is scenery in the Observation Car. The description of the floor is "Solid metal underneath carpet. No holes or hatches of any kind. You've already checked."

Understand "solid" or "metal" as the floor.
	
The vivid chartreuse carpeting is scenery in Observation Car. Understand "carpet" as the vivid chartreuse carpeting. The description of the vivid chartreuse carpeting is "The entire observation car is covered in high-quality nylon, one of the first carpets of its kind. It's colored a lovely shade of chartreuse."

Understand "nylon" as the vivid chartreuse carpeting.

The realcar is scenery in Observation Car. Understand "observation" or "car" or "room" as the realcar.

Instead of examining the realcar:
	try looking;

Report opening the presumptuously ornate door:
	say "The metal door opens with a screech."

Report closing the presumptuously ornate door:
	say "The metal door closes with a screech."

Section 3 - Darkness Transitions

DarkCounter is a number that varies. DarkCounter is 0.

TunnelTime is a recurring scene. Tunneltime begins when DarkCounter >  8.

Every turn:
	if the player is in Observation Car:
		if TunnelTime is not happening:
			now DarkCounter is DarkCounter plus one;

When TunnelTime begins:
	now Observation Car is dark;
	say "The train passes under a tunnel, plunging the room into darkness[first time].[paragraph break]Cornelia tuts. 'We really ought to get better lighting in here,' she says[only].";
	now DarkCounter is 0;

TunnelTime ends normally when the time since TunnelTime began is 2 minutes;

SkipFlag is a number that varies. SkipFlag is 0;

TunnelTime ends abruptly when SkipFlag is 1;

TunnelFlag is a number that varies. TunnelFlag is 0.

When TunnelTime ends:
	now TunnelFlag is 1;
	now SkipFlag is 0;
	now Observation Car is not dark;
	say "The train exits the tunnel, and sunlight [if the shades are not drawn]streams in once more.[otherwise]filters weakly through the shades.[end if]";
	trigger the count's notice;

Before looking:
	if TunnelFlag is 1:
		now TunnelFlag is 0 instead;

Understand the command "skip" as something new.

TimeSkipping is an action applying to nothing. Understand "skip" as TimeSkipping.

Carry out TimeSkipping:
	if the player is not in observation car:
		say "There's nothing to skip out here!";
		stop the action;
	if in darkness:
		say "You wait for the train to leave the tunnel.";
		now SkipFlag is 1;
	otherwise:
		say "You wait for a tunnel to darken the car.";
		now DarkCounter is 9;

Chapter 2 - Events

The ticket is carried by the player. The description of the ticket is "Buying these every week has been a small drain on your resources, but it will soon be worth it."

Every turn:
	if the player is in Observation Car:
		if Observation Car is not dark:
			if the server is not in Observation Car:
				if a random chance of 1 in 4 succeeds:
					send in the clowns;
	if the presumptuously ornate door is open:
		try the attendant closing the presumptuously ornate door;
		
To send in the clowns:
	say "[one of]The conductor peeks in.[tickettake][or]A photographer enters the room and snaps a few pictures. You move discreetly out of the way. [ViscountHide][or][randomtexttime][stopping]";

Section 1 -Taking Tickets

To say tickettake:
	if the ticket is enclosed by the player:
		say "[line break]You [if the Viscount is in observation car]and the Viscount wave your tickets[otherwise]wave your ticket[end if] at the conductor, and he takes them. With a salute at [the attendant], the conductor leaves the room.";
		now the ticket is nowhere;
	otherwise:
		say "[line break]Your ticket. Where is your ticket? You look for it, but the conductor has already grabbed you by the arm and thrown you off the car.";
		end the story saying "Another week, another disguise. Time to try again!";

Section 2 - Viscount hiding

To say ViscountHide:
	if the Viscount is in Observation Car:
		if the wide hat is worn by the Viscount:
			say "You notice the Viscount pulling his hat over his eyes. ";
		otherwise:
			say "You notice the Viscount burying his face into [a random thing worn by the Viscount] to hide. ";
	say "The photographer takes a couple more and departs.";

Section 3 - Random text 

To say randomtexttime:
	say "[one of]You hear the whistle blow.[or]There is a murmur of voices in the outside corridor, but it subsides.[or]An official-looking woman enters with a document for Hogg to sign. Hogg scrawls on the line without looking up and the woman leaves.[or]An up-and-coming socialite enters the room and stands in awe of Ms. Hogg's presence. After trying to engage you all in small talk, the visitor leaves.[at random]"

Book 2 - People

Part 1 - Sir Rodney Playfair

Chapter 1 - Playfair Himself

Section 1 - Basics

Rodney Playfair is a man. The player is Rodney Playfair. Understand "rodney" or "playfair" or "alias" or "magpie" or "sir" as Rodney Playfair.

Section 2 - Description

The description of Rodney Playfair is "You are Sir Rodney Playfair: dashing, debonair, and devilishly handsome. Not perhaps in the first flush of youth, but very sprightly for a man of sixty. That touch of grey at the temples lends you an air of authority, a useful attribute for getting one out of a scrape.

You are currently wearing [a random costume worn by the player]."

Chapter 2 - Rodney's Items

Section 1 - Clothing

[The tweed suit is worn by the player. The description of the tweed suit is "A rather natty herringbone tweed, complete with a secret inside pocket." Understand "natty" or "herringbone" as the tweed suit.

The secret pocket is part of the tweed suit. The secret pocket is a container. Understand "inside" as the secret pocket.

The description of the secret pocket is "A handy place to stash the loot, and to keep the tools of your trade. The pocket presently contains [the list of things enclosed by the secret pocket]."]

Section 2 - Initial Inventory

The feather is in the suitcase. The description of the feather is "[if the feather is enclosed by the player]The distinctive feather of [italic type]Pica pica[roman type], of the family [italic type]Corvidae;[roman type] the unmistakable calling card of the notorious [']Magpie[']. 

You plan to drop it before you go. It's pure vanity, of course, but you'd hate for someone else to take credit for your work.

You have it discreetly hidden for now.[otherwise]The feather is laying near Cornelia Hogg. It is unnoticed.[end if]" 

Understand "black" or "white" as the feather. The printed name of the feather is "black and white feather".

Before dropping the feather:
	if the player is not carrying the Gavinchian rose:
		say "Revealing your presence seems like a bad idea, wouldn't you say?" instead;
	otherwise:
		if the feather is in the suitcase:
			now the suitcase is open;
		say "You gently lay the feather next to Cornelia Hogg. Very nice.";
		now the feather is in Observation car instead;

Before wearing the feather:
	say "That's a little too obvious, don't you think?" instead;
		
Before taking the feather:
	if the feather is in the suitcase:
		say "You open the suitcase a crack.";
		now the suitcase is open;

Instead of taking the feather:
	if the player is not carrying the Gavinchian rose:
		say "The feather is your signature, which you leave after every successfully completed crime. Revealing your presence seems like a bad idea, wouldn't you say?" instead;
	otherwise:
		if the feather is in the suitcase:
			say "You discreetly open the suitcase and fetch the feather out.";
			now the feather is carried by the player;
		otherwise if the feather is carried by the player:
			say "You're already holding the feather!";
		otherwise:
			say "Revealing your presence seems like a bad idea, wouldn't you say?" instead;
	
Before showing the feather to someone:
	say "You've made a habit of not revealing your true identity while engaging in crime. It would be a shame to do so now." instead;

Before giving the feather to a person (called featherTaker):
	if the player is not carrying the Gavinchian rose:
		say "You aren't the type to sabotage yourself." instead;
	otherwise:
		if featherTaker is Hogg:
			try dropping the feather instead;
		otherwise:
			say "That's not a good person to give it to. After all, you took the Rose from Hogg, didn't you?" instead;

Chapter  3 - Costumes

Section 1 - Starting Costumes

CurrentAlias is a number that varies. CurrentAlias is 0.

A costume is a kind of thing. A costume is always wearable.

A costume can be stinky or not stinky. A costume is usually stinky. A costume has some text called the smell. The smell of a costume is usually "like mothballs".

A costume can be introduced or not introduced. A costume is usually not introduced.
A costume can be greeted or not greeted. A costume is usually not greeted.
A costume can be familiarized or not familiarized. A costume is usually not familiarized.

[Introduction is for Hogg, greeting is for foxtrot]
A costume has some text called the introduction. The introduction of a costume is usually "'Good afternoon, Ms. Hogg.'"

A costume has some text called the familiarity. The familiarity of a costume is usually "'You seem familiar, sir. Have we met?' you ask pointedly.

'You must be mistaken,' answers the Viscount in a gruff tenor.  'I rarely travel from my estate.'

'Of course, your estate. A pleasant one, I suppose, as you are the Viscount of...?' you press. 

The Viscount shakes his head. 'It's a new one, you wouldn't have heard of it.'

'Ah, such modesty. It's surprising, though. Only three viscountcies were granted this year, and I am personally acquainted with two of them. I suppose that you, then, are the Viscount Upton Snodsbury.'

The Viscount says, 'Oh! Yes, yes. Upton Snodsbury.'".

A costume has some text called the greeting. The greeting of a costume is usually "You give a small bow, letting her see your [Costumes in row CurrentAlias of the Table of Aliases]. [PithyPhrase in row CurrentAlias of the Table of Aliases][paragraph break]'Very well, [honorific in row CurrentAlias of the Table of Aliases],' she says. 'You will be permitted to visit Ms. Hogg's observation car. The following are prohibited: solicitation, disorderly behavior, religious proselytising, sales pitches, unlicensed scientific research, fireworks, poking the parrot, and wearing disguises.'

'Of course, ma'am. I wouldn't think of it,' you say. The attendant beckons you to follow her into the train to the east."

The military costume is a costume. The description of the military costume is "There's a stiff mustache that you assembled over the last few weeks, hair by hair.  The worn three-piece suit completes the ensemble." Understand "mustache" or "three-piece" or "three" or "piece" or "suit" as the military costume. The smell of the military costume is "like gunpowder".

The introduction of the military costume is "'Good afternoon, Ms. Hogg.'

She looks at you skeptically. 'Good afternoon, Mister...'

'Springbottom. Major Springbottom, in fact.  I've seen quite a few terrible things in the service, but I'm pleased to say I've never seen anything quite like you. Charmed, I'm sure.'

'Yes, yes,' she mutters, returning to her papers. 'Charmed.'"

The doctor costume is a costume. The description of the doctor costume is "You didn't go so far as to include a stethoscope, but your white suit coat and keen expression are enough." Understand "stethoscope" or "keen" or "expression" as the doctor costume. The smell of the doctor costume is "like antiseptic".

The introduction of the doctor costume is "'Good afternoon, Ms. Hogg.'

She looks at you skeptically. 'Good afternoon, Mister...'

'Oh, it's Doctor. My name is Dr. Weatherford, and it's a pleasure to meet you, Ms. Hogg.'

'I'm sure,' she says. 'But I hope you aren't looking for a new client. I've had a respectable, reliable family doctor for years.'

'No, no, Ms. Hogg, I just wished to be graced with your presence. In fact, I'm a veterinarian by trade, and I can say that by the looks of you, you'd take first prize in one of your American fairs!'

'Excuse me?'

'You're excused,' you say, with a polite bow. 'My, what a lovely rail car.'"

The professor costume is a costume. The description of the professor costume is "A quick stop at a second-hand shop earned you this tacky sport jacket." Understand "tacky" or "sport" or "jacket" as the professor costume. The smell of the professor costume is "like chalk".

The introduction of the professor costume is "'Good afternoon, Ms. Hogg.'

She looks at you skeptically. 'Good afternoon, Mister...'

'Professor Spinwater, at your service.'

'And just what are you a professor of, Mr. Spinwater?'

'Philosophy, Ms. Hogg. My thesis was on the Stoics, who believed that, with effort, one can become resistant to emotional distress and all other misfortunes of life. I've been experimenting on my theories, you know. In any case, I've been looking forward to spending some time in your company!'"

The aristocrat costume is a costume. The description of the aristocrat costume is "You obtained the cuff links and monocle completely legitimately, however surprising that may be. The rest of the ensemble is not far from your day-to-day dress." Understand "cuff links" or "cuff link" or "cuff" or "link" or "monocle" as the aristocrat costume. The smell of the aristocrat costume is "like mothballs"

The introduction of the aristocrat costume is "'Good afternoon, Ms. Hogg.'

She looks at you skeptically. 'Good afternoon, Mister...'

'Sir Highwater, CBE, SGM, QED. At your service.' You bow as slightly as possible.

'I see,' says Ms. Hogg flatly.

'I had heard you had a bit of a fancy rail car to show off. I do hope we see it at some point, but I suppose this will do for now.'

'This is my only rail car, Mr. Highwater.'

'Indeed? Must be this new monocle, it does distort things so. My, what an attractive suit you're wearing.'"

CurrentCostume is a thing that varies. CurrentCostume is the doctor costume.

Instead of taking off CurrentCostume:
	DisguiseLose;

Instead of dropping CurrentCostume:
	DisguiseLose;
	
To DisguiseLose:
	say "[the attendant] turns to you immediately in suspicion. Without your carefully-crafted disguise, you have been outed as an impostor. 

Her hand slips in her pocket, and you can see the outline of a firearm. 'I'm going to have to ask you to leave, [the Honorific in row CurrentAlias of the Table of Aliases]. '

You bow, and make your exit.";
	end the story saying  "You'll prepare, and return next week."

When play begins:
	let n be a random number from 1 to the number of rows in the Table of Aliases;
	now CurrentAlias is n;
	now CurrentCostume is Costumes in row CurrentAlias of the Table of Aliases;
	now Currentcostume is worn by the player;


Table 1 - Aliases
Alias	Honorific	Costumes	PithyPhrase
"Major Springbottom"	"Major"	military costume	"'It was my turn to be demobbed, ma'am, and I thought I'd take a ride on the best rail car the States can muster up before heading back. Spent a pretty penny, too!'"
"Doctor Weatherford"	"Doctor"	doctor costume	"'The engineer conductor said I should ride in this car. In case my services are required.'"
"Professor Spinner"	"Professor"	professor costume	"'I've made a study of luxury rail cars, and I've heard that this one is the jewel of the west. May I observe it?'"
"Sir Highwater"	"Sir"	aristocrat costume	"'I believe Ms. Hogg is a distant relation on the distaff side. It's all rather dull, I know, but I thought I might make an appearance, seeing I'm in the area.'"


Section 2 - The suitcase

The suitcase is a player's holdall. Understand "case" as the suitcase. The suitcase is carried by the player. The suitcase is transparent. The suitcase is closed. The description of the suitcase is "This suitcase contains a number of ingenious costumes. You can change costumes by typing WEAR [bracket]the costume you want[close bracket] when everyone is distracted."

Instead of dropping the suitcase:
	say "The entirety of your plan rides on this suitcase. Dropping it would be fairly foolish, and the Magpie is never foolish."

After deciding the scope of the player while in darkness: place the suitcase in scope.

After deciding the scope of the player while in darkness: place the Rose in scope.

Every turn:
	if the suitcase is open:
		say "You close the suitcase.";
		now the suitcase is closed;

Before examining something when in darkness:
	if the noun is the suitcase:
		say "You remember that the suitcase contains [a list of costumes enclosed by the suitcase]." instead;
	otherwise if the noun is a quip:
		say history of the noun;
		
Report opening the suitcase:
	say "You take a quick peek inside the suitcase.";
	try examining the suitcase instead;

Section 3 - Changing clothes

A costume has some text called DonningText. The DonningText of a costume is usually "It fits perfectly."

[Before examining something:
	if in darkness:
		say "It's too dark to see anything right now."]

[RenewedFlag is just there to make the renewal of introductions appear at the end of the text]
RenewedFlagA is a number that varies. RenewedFlagA is 0.
RenewedFlagB is a number that varies. RenewedFlagB is 0.
RenewedFlagC is a number that varies. RenewedFlagC is 0.

Before taking a costume:
	if the noun is not worn by the player:
		now the suitcase is open;

Instead of taking a costume:
	if the noun is worn by the player:
		say "You are currently disguised with [the noun].";
	otherwise if the player is in Station:
		say "The attendant may not let you enter in a different costume than the one she just saw you in.";
	otherwise if not in darkness:
		say "No, not where everyone can see you. Experience has taught you to wait for better lighting.";
	otherwise:
		repeat with current running through costumes worn by the player:
			now current is in the suitcase;
			say "You take off [the current] and put it in the suitcase, then pull out [the noun]. [DonningText of the noun][line break]";
		now the noun is worn by the player;
		if the noun is not introduced:
			now Introductions is not TargetGiven;
			now RenewedFlagA is 1;
		if the noun is not greeted:
			now Greetings is not TargetGiven;
			now RenewedFlagB is 1;
		if the noun is not familiarized:
			if the Viscount is in Observation Car:
				now Familiar is not TargetGiven;
				now RenewedFlagC is 1;

Before wearing a costume:
	if the noun is not worn by the player:
		say "You open the suitcase a crack.";
		now the suitcase is open;

Instead of wearing a costume:
	try taking the noun instead;
			
Every turn:
	if RenewedFlagA is 1:
		say "[bracket]Renewed topic for Cornelia Hogg - [bold type]Introductions[roman type][close bracket][line break]";
		now RenewedFlagA is 0;

Every turn:
	if RenewedFlagB is 1:
		say "[bracket]Renewed topic for [the attendant] - [bold type]Greetings[roman type][close bracket][line break]";
		now RenewedFlagB is 0;

Every turn:
	if RenewedFlagC is 1:
		say "[bracket]Renewed topic for the Viscount - [bold type]Familiar[roman type][close bracket][oncenotify]";
		now RenewedFlagC is 0;

To say oncenotify:
	say "[first time][paragraph break][bracket]You can introduce yourself to Hogg, the Viscount and/or the attendant once per costume.[close bracket][only][line break]"
	

A costume can be ViscountNoticed or not ViscountNoticed. A costume is usually not ViscountNoticed.

When play begins:
	repeat with current running through costumes worn by the player:
		now current is ViscountNoticed;

To trigger the count's notice:
	repeat with current running through costumes worn by the player:
		if current is not ViscountNoticed:
			if Viscount is in Observation Car:
				say "[line break]The Viscount turns and looks at your new disguise, then goes back to his magazine. He seems to be the only one who's noticed.";
			now current is ViscountNoticed;
	repeat with current running through costumes not worn by the player:
		now current is not ViscountNoticed;

[A costume can be HoggNoticed or not HoggNoticed. A costume is usually not HoggNoticed.

Every turn:
	if the pet groomer costume is not HoggNoticed:
		if the pet groomer costume is worn by the player:
			if not in darkness:
				now the pet groomer costume is HoggNoticed;
				say "Hogg looks up at you and says, 'Ah, you're finally here. Give him the usual.' 

She reaches into a pocket and pulls out a grooming kit, which she tosses on the floor.";
				now the grooming kit is in Observation Car;]

Section 4 - The other costumes

[Interaction between server and waiter costumes?]

[add synonyms for things?]

The banker costume is a costume. The banker costume is in the suitcase. The banker costume is not stinky. The smell of the banker costume is "like dollar bills". DonningText of the banker costume is "You tug on the suit in record time. You straighten your spine, put on a sardonic smile, and nudge every hair into place.

You can hear Cornelia Hogg sniffing. 

'What is that pleasant odor?' she mutters. 

Good. At least your smell won't disturb Ms. Hogg when you try to take the Rose."

The description of the banker costume is "A suit, a smile, and the odor of money is all you need."

The introduction of the banker costume is "'Good afternoon, Ms. Hogg.'

She looks at you with admiration. 'And a good afternoon to you, sir. Please, make yourself comfortable. It's always a pleasure to see a representative of our financial industries aboard.' She takes a deep sniff, which you find fairly unsettling.

'Of course. As for me, whenever I think about the great problems of labor and wealth distribution in America, your face is the first to come to mind. It is an honor, Madame.'"

The greeting of the banker costume is "You make a tiny bow towards the attendant.

She approaches you eagerly. 'I didn't see you come in, M--'

'No matter, no matter, my dear. My employers are quite interested in speaking with Ms. Hogg.' You look her up and down. 'Would you say that you are a typical representative of the quality of Ms. Hogg's entourage?'

'Yes, I would say that's quite right,' she answers, blushing and squaring her shoulders.

'Well, I suppose we all make do,' you say. 'Carry on.'"

The familiarity of the banker costume is "'You seem familiar, sir. Have we met?' you ask.

The Viscount sighs and buries his face in the magazine. 'No, I don't believe so.'

'Do you have interest in the world of finance? We could use people with a strong work ethic and integrity,' you ask.

'I am of independent means, sir,' answers the Viscount haughtily.

'Well,' you say, 'we might still be able to use someone with just integrity. Let me know!'"

The waiter costume is a costume. The waiter costume is in the suitcase. The smell of the waiter costume is "like beef gravy". DonningText of the waiter costume is "Shirt, pants, and apron all go on quickly. You slightly compress yourself and mute your expressions. Inconspicuity emanates from you."

The description of the waiter costume is "You managed to find one of these in your size on a previous trip."

The introduction of the waiter costume is "'Good afternoon, Ms. Hogg.'

[The attendant] is scandalized. 'You do not address Ms. Hogg! Remember your place! And no spills!'

Hogg glares at [the Attendant], and says, 'Beatrice, remember your own place!'"

The greeting of the waiter costume is "You make a small bow towards [the attendant].

'Get me a soda,' she says. 'Plain.'[SodaFlag]"

The familiarity of the waiter costume is "'You seem familiar, sir. Have we met?' you ask.

He looks you over and turns away. 'No.' 

[The attendant] hurries over. 'Pardon me, Viscount. Is this servant bothering you?' she asks, glaring at you.

You hold up your hands in protest. 'No, no, sorry. I just thought I had met him before. I'm well-known among the staff for my encyclopedic knowledge of famous faces. I know by heart the visages of the great, the noble, the beautiful, and the wise.'

[The attendant] looks at the Viscount with interest. 'Well, do you know him?'

You make a show of peering closer. 'Sorry, no. My mistake.'"

NeedsSoda is a number that varies. NeedsSoda is 0.

To say SodaFlag:
	now NeedsSoda is 1;
	
Before giving the glass of soda to the attendant:
	if NeedsSoda is 1:
		now NeedsSoda is 0;
		now the glass of soda is on the tray full of drinks;
		say "'Your drink, ma'am,' you say.

'Finally,' she says. She chugs the whole drink at once. The attendant steps out for a moment to grab more soda before returning.

Ms. Hogg says, 'Beatrice, that's crass. Drink it slowly!' Beatrice rolls her eyes." instead;
	otherwise:
		say "Beatrice shakes her head. 'No thanks.'" instead;

Instead of giving the glass of water to the attendant:
	say "[The attendant] says, 'No, thank you. The lavatory is at the other end of the train and I don't want to leave my post until we arrive.'"

Instead of giving the glass of grape juice to the attendant:
	say "[The attendant] says, 'No. My employer drinks so much of it that the smell of it has begun to sicken me.'"

Instead of giving the glass of vodka to the attendant:
	say "[The attendant] says, 'You won't see me drinking on the job. Not after last time!'"

Instead of giving a mixed beverage to the attendant:
	say "[The attendant] sniffs it and says, 'What is this awful concoction?'"

Before examining a costume:
	if the noun is enclosed by the suitcase:
		say "While you can't see it inside the suitcase, you remember what it looks like.";
		if in darkness:
			say "[line break]";
			say the description of the noun;
			say "[line break]" instead;

Before examining the feather:
	if the noun is enclosed by the suitcase:
		say "While you can't see it inside the suitcase, you remember what it looks like.";
		if in darkness:
			say "[line break]";
			say the description of the feather;
			say "[line break]" instead;

The maintenance uniform is a costume. The maintenance uniform is in the suitcase. The smell of the maintenance uniform is "like machine oil and dust". DonningText of the maintenance uniform is  "The jumpsuit is an easy fit. You adopt an attitude of confidence in yourself and indifference to those around you."

The introduction of the maintenance uniform is "'Good afternoon, Ms. Hogg.'

She glares at you. 'What's the matter now? Another useless drain on my money, or a pointless waste of my time?'

'Oh, I'm firmly against pointless wastes of time,' you say. 'I'll continue with my inspection, now.'"

The greeting of the maintenance uniform is "You make a slight bow towards [the Attendant]. She seems completely oblivious to your presence."

The familiarity of the maintenance uniform is "'You seem familiar, sir. Have we met?' you ask.

The Viscount mutters some noncommittal noises.

You place your hands on your hips and lean in closer, squinting your eyes. 'Begging your pardon, but you remind me of my late uncle Melvin. Did you know a Melvin Flathead?'

The Viscount, says, 'No, I'm sorry, I haven't heard of him.'

'That's a shame, sir. He always had a bright personality, which was just as well for him. The firstborn gets the looks in our family, and, well, Melvin was the eighth child.'"

The description of the maintenance uniform is "A lightly greased jumpsuit with an almost indistinguishable monogram."

Understand "jumpsuit" or "indistinguishable" or "monogram" as the maintenance uniform.

The pet groomer costume is a costume. The pet groomer costume is in the suitcase. The smell of the pet groomer costume is "a little bit like dung". DonningText of the pet groomer costume is "The clothing is simple, and the attitude is one of youth and enthusiasm."

The description of the pet groomer costume is "This is technically a zoo-keeper outfit. It's the smell that makes all the difference."

The introduction of the pet groomer costume is "'Good afternoon, Ms. Hogg.'

Without looking up, she says, 'Ah, finally. Give Horus a good filing, and be quick about it. I hope you're qualified. Horus is a bit of a beast.' 

She grabs a grooming kit from her lap, which she tosses on the floor.[giveStuff]

'No problem, ma'am. I'm quite used to the company of unpleasant old birds. I'll get started right away!'"

The greeting of the pet groomer costume is "You make a small bow towards the attendant. She looks your way but wrinkles her nose and turns back."

The familiarity of the pet groomer costume is "'You seem familiar, sir. Have we met?' you ask.

He shakes his head, studiously reading his magazine instead of looking at you.

'No, you remind me of someone. A Viscount, I heard you were? I attended a birth for a Viscount once. He had a few farm animals on his estate as an affectation. I attended his ewe on occasion when she had her litters. Now, you don't look like him much, but I thought there was a resemblance of some sort....' you muse thoughtfully.

'Ah!' you say, snapping your fingers. 'It was the sheep! Darling little thing.'"

To say giveStuff:
	now the grooming kit is in Observation Car;

Instead of smelling a costume:
	if in darkness:
		say "You take a few sniffs of the outfit. It smells like [the smell of the noun].";
	otherwise:
		say "You take a few sniffs of the outfit. It smells like [the smell of the noun].";
		
Instead of smelling the player:
	if in darkness:
		try smelling a random costume worn by the player;
	otherwise:
		try smelling a random costume worn by the player;

Instead of smelling the viscount:
	if in darkness:
		say "The Viscount has a nasty sort of chemical smell, sickly-sweet and pungent.";
	otherwise:
		say "The Viscount has a nasty sort of chemical smell, sickly-sweet and pungent.";

Instead of smelling something:
	if in darkness:
		say "You can't smell [the noun] over the various other odors in the room.";
	otherwise:
		say "You can't smell [the noun] over the various other odors in the room.";

Section 5 - Danger

Every turn:
	if the player is not wearing a costume:
		if not in darkness:
			DisguiseLose;

Chapter 4 - Speech

Section 1 - Quips

A quip is a kind of thing. 

A quip has a person called the target. The target of a quip is usually the parrot.

A thing can be physical or not physical. A thing is usually physical.

A quip is a kind of thing.  A quip is never physical. A quip has some text called the preview. The preview of a quip is usually "Insert preview here.". A quip has some text called history. 

A quip can be TargetGiven or MeihTarget. A quip is usually MeihTarget.

A quip has some text called TargetResponse. The TargetResponse of a quip is usually "Horus doesn't seem interested in that.". 

A quip has some text called TargetSummary. The TargetSummary of a quip is usually "You tried talking about this with Horus.".

Rule for deciding whether all includes quips: it does not.

Instead of inserting a quip into a container:
	say "That's not a physical object.";

Instead of putting a quip on a supporter:
	say "That's not a physical object.";

Understand "recall [something]" or "remember [something]" as examining.

Section 2 - Quip dynamics

After printing the name of a quip (called currentquip) when topicing:
	Say " - [the preview of currentquip]".

Instead of examining a quip (called currentquip):
	say history of currentquip;

A quip can be deliveryflagged or not deliveryflagged. A quip is usually not deliveryflagged.

To deliver (currentquip - a quip):
	if currentquip is carried by the player:
		rule succeeds;
	otherwise:
		now currentquip is deliveryflagged;

Introductions is a quip. Hello is a quip. Familiar is a quip. Greetings is a quip. Understand "introduction" as introductions. Understand "intro" as introductions. Understand "Greeting" as greetings.
		
Report looking for the first time:
	deliver Greetings;
	repeat with currentquip running through deliveryflagged quips:
		say "[bracket]New topic for [the target of currentquip] - [bold type][currentquip][roman type][close bracket]";
		say "[line break]";
		now history of currentquip is "[preview of currentquip]";
		now currentquip is carried by the player;
		now currentquip is not deliveryflagged;
	say "[line break][bracket]You can talk to the attendant by typing SAY GREETINGS[close bracket][paragraph break]"

Every turn:
	repeat with currentquip running through deliveryflagged quips:
		say "[bracket]New topic for [the target of currentquip] - [bold type][currentquip][roman type][close bracket]";
		say "[line break]";
		now history of currentquip is "[preview of currentquip]";
		now currentquip is carried by the player;
		now currentquip is not deliveryflagged;

Understand the command "say" as something new.

Understand the command "destroy" as something new.

Singlespeeching is an action applying to one thing. Understand "say [something]" or "tell [something]" or "t [something]" or "a [something]" as singlespeeching.

Speeching it to is an action applying to two things. Understand "say [something] to [someone]" or "tell [something] to [someone]" or "t [something] to [someone]" or "a [something] to [someone]" as speeching it to.

Carry out singlespeeching:
	if in darkness:
		say "It's hard to tell who's here in the darkness with you. Better to wait.";
	otherwise if the noun is a quip:
		try speeching the noun to the target of the noun;
	otherwise:
		say "That's not something you can say.";

Does the player mean singlespeeching something:
	it is very likely;
	
Keywording is an action applying to one thing. Understand "[something]" as keywording.

Carry out keywording:
	if the noun is not a quip:
		say "You need to supply a verb.";
	otherwise:
		if the number of people in the location of the player is at least two:
			try singlespeeching the noun;
		otherwise:
			say "There is no one to talk to here.";

HelpfulText is some text that varies. HelpfulText is "[line break][bracket]You can REMEMBER or RECALL a topic to remind yourself about previous conversations.[close bracket][line break]"

Carry out Speeching it to:
	if in darkness:
		say "It's too dark to find the person you're talking to!";
	otherwise:
		if the noun is not a quip:
			say "You can only discuss your current thoughts as listed in your topics.";
		otherwise if the noun is not carried by the player:
			say "That's not a topic you currently possess.";
		otherwise if the second noun is not a person:
			say "You can only do that to something animated.";
		otherwise:
			set pronouns from the second noun;
			if the second noun is the target of the noun:
				if the noun is MeihTarget:
					say TargetResponse of noun;
					if the noun is destroy:
						do nothing;
					otherwise if the noun is reject:
						do nothing;
					otherwise:
						say "[line break]"; 
					now the noun is TargetGiven;
					now history of the noun is "[Preview of noun][paragraph break][TargetSummary of noun][line break]";
				otherwise:
					say "You've already discussed this with [Target of the noun].[HelpfulText]";
			otherwise:
				say "That topic can only discussed with [the target of the noun]."

Helloing is an action applying to one thing. Understand "greet [someone]" as helloing.

SingleHelloing is an action applying to nothing. Understand "hello" as singlehelloing.

Carry out singlehelloing:
	try singlespeeching Hello;

Carry out helloing:
	try speeching hello to the noun;
	
QuerySmalling is an action applying to two things. Understand "ask [something] to [someone]" as querysmalling.

Carry out QuerySmalling:
	try speeching the noun to the second noun. 

Querying it to is an action applying to two things. Understand "ask [someone] about [something]" as querying it to.

Carry out querying:
	try speeching the second noun to the noun;

Talking to is an action applying to one thing. Understand "talk to [someone]" as talking to.

CurrentPerson is some text that varies. CurrentPerson is "the parrot".

To say CapPerson:
	say "[CurrentPerson in upper case]";

Carry out talking to:
	if the noun is the player:
		say "While you are a witty and jovial conversational partner, it may be better to talk with others.";
	otherwise if the noun is the server:
		say "The server avoids eye contact and says nothing.";
	otherwise if the noun is a person:
		now CurrentPerson is "[the noun]";
		say "To speak with [the noun], choose a topic from below and SAY [bracket]the topic[close bracket] TO [CapPerson].[paragraph break]";
		let counterThing be 0;
		repeat with currenttwo running through quips carried by the player:
			if the target of currenttwo is the noun:
				increment counterThing;
		if CounterThing > 0:		
			say "[bold type]Things to say to [the noun]:[roman type]";
			repeat with currentquip running through all quips carried by the player:
				if Target of currentquip is the noun:
					say "[line break]   ";
					say currentquip;
			say "[line break]";
		otherwise:
			say "[bold type]Things to say to [the noun][roman type][line break]    You can't think of anything at this time.[line break]";


Section 3 - Inventory

Check dropping a quip (called currentquip):
	say "You never forget." instead;
	
EmptyText is some text that varies. EmptyText is "[line break]   nothing".

Oncecrackered is a number that varies. Oncecrackered is 0. 

Instead of taking inventory:
	now oncecrackered is 0;
	say "You are carrying:";
	repeat with currentitem running through physical things carried by the player:
		now EmptyText is "[line break] ";
		if currentitem is a container:
			say "[line break]   [a currentitem], [if currentitem is open]open[otherwise]closed[end if], containing [a list of things enclosed by currentitem]";
		otherwise if currentitem is a cracker:
			if oncecrackered is 0:
				say "[line break]   [the number of crackers carried by the player] cracker[if the number of crackers carried by the player > 1]s[end if]";
				now oncecrackered is 1;
		otherwise:
			say "[line break]   [a currentitem]";
	say "[EmptyText][first time][line break][bracket]You can see topics for speaking to others by typing T or TOPICS[close bracket].[only]";
	now EmptyText is "[line break]   nothing.";

Topicing is an action out of world. Understand "t" or "topics" or "thoughts" as topicing.

Carry out topicing:
	say "[bracket]Topics with an asterisk (*) have already been discussed.[close bracket][paragraph break]";
	repeat  with current running through people in the location of the player:
		if current is the server:
			do nothing;
		otherwise if current is the player:
			do nothing;
		otherwise:
			let counterThing be 0;
			repeat with currenttwo running through quips carried by the player:
				if the target of currenttwo is current:
					increment counterThing;
			if CounterThing > 0:		
				say "[bold type]Things to say to [the current]:[roman type]";
				repeat with currentquip running through all quips carried by the player:
					if Target of currentquip is current:
						if currentquip is targetgiven:
							say "[line break]  *";
						otherwise:
							say "[line break]   ";
						say currentquip;
				say "[line break]";
			otherwise:
				say "[bold type]Things to say to [the current][roman type][line break]    You can't think of anything at this time.[line break]";
	say "[line break]You can see just the topics for one person at a time by TALKing TO that person."


Part 2 - Cornelia Hogg

Chapter 1 - Hogg Herself

Cornelia Hogg is a woman. "Cornelia Hogg is poring over her papers, mumbling and making minor adjustments." The description of Cornelia Hogg is "Cornelia Hogg is a weathered, wiry old woman with a sharp gleam in her eye. Her attention is entirely devoted to the papers she is reviewing while occasionally clucking her tongue. Hogg is dressed in a perfectly-tailored pin-striped pantsuit. Her brow is perpetually furrowed, and she has a thick head of silver hair.

The Gavinchian Rose, the object of your desire, is[if the Gavinchian Rose is not worn by Cornelia Hogg] no longer[end if] prominently displayed on her lapel[if the grooming kit is carried by Cornelia Hogg]. A pet grooming kit lies on her lap[end if]."

The pin-striped pantsuit is worn by Cornelia Hogg. The description of the pin-striped pantsuit is "Admittedly, it's quite tasteful." The lapel is part of the pin-striped pantsuit. The description of the lapel is "Perfect for pinning things on."

The furrowed brow is part of Cornelia Hogg. The description of the furrowed brow is "Cornelia seems constantly in thought."

The thick head of silver hair is part of Cornelia Hogg. The description of the thick head of silver hair is "It looks burnished and soft."

The papers are carried by Cornelia Hogg. Understand "paper" or "tables" or "numbers" or "figures" or "number" or "figure" or "dense" as the papers.

The description of the papers is "The papers are covered in dense tables of numbers and figures."

Cornelia Hogg is in Observation Car.

Chapter 2 - Hogg's accouterments

The Gavinchian Rose is worn by Cornelia Hogg. The description of the Gavinchian Rose is  "Your heart breaks a little every time you look at it. The organic asymmetry of the petals ranks among the top five most beautiful works of art you've ever seen. [if the gavinchian rose is worn by Cornelia Hogg]You must possess it!

In fact, you could always try to take it. You're talented enough to stop in time if it looks like you'll be caught.[otherwise]And now it's yours! At last![end if]"

Understand "gem" or "petals" or "art" or "jewel" or "ruby" as the gavinchian rose.

The can't take people's possessions rule does nothing if the current action is taking the Gavinchian Rose.

Instead of showing the Gavinchian Rose to someone:
	say "Seriously? No.";

Instead of giving the Gavinchian Rose to someone:
	say "Seriously? No.";

Instead of dropping the Gavinchian Rose:
	say "That's not your style.";

Chapter 3 - Progress

[Might be deletable]

HoggSenses is a number that varies. HoggSenses is 5.

Section 1 - Sight

The windows are scenery in Observation Car. Understand "window" as the windows.

The description of the windows is "[if the shades are not drawn]Bright sunlight streams through the windows, unblocked by the fully opened shades.[otherwise]The shades block most of the light from outside.[end if]"

The shades are scenery in Observation Car. The shades are plural-named. A thing can be drawn or not drawn.  The shades are not drawn. Understand "blind" or "shade" or "blinds" as the shades. The description of the shades is "A simple set of shades, not quite up to the standard of the rest of the car. But they're thick enough. They are currently [if the shades are drawn]closed[otherwise]open[end if]."

Understand "draw [something]" as pulling. Understand "lower [something]" as pulling. 

Understand "shade [something]" as closing.

Understand "raise [something]" as opening.

Before closing the windows:
	try closing the shades instead;

Before closing the shades:
	if the shades are not drawn:
		try pulling the shades instead;
	otherwise:
		say "They are already closed." instead;

Before opening the shades:
	if the shades are drawn drawn:
		try pulling the shades instead;
	otherwise:
		say "They are already open." instead;

The shadow is part of Rodney Playfair. The description of the shadow is "It's your shadow. It looks like you, except flat and made of the absence of light. Handsome, though."

Instead of touching, taking, smelling, tasting, rubbing, swinging, pushing, pulling, dropping, eating, looking under, attacking, or searching the shadow:
	say "Your shadow is immaterial. It imitates your feeble attempts at interacting with it, but (predictably) nothing else happens."

Before pulling the shades:
	if the shades are not drawn:
		if the maintenance uniform is not worn by the player:
			say "[The attendant] looks over sharply. 'Leave those alone, you wretched man! That's for railroad maintenance only!'" instead;
		otherwise:
			now the shades are drawn;
			say "You pull down the shades. [if the maintenance uniform is not greeted][The attendant] says, 'Leave those alone, you--' but cuts off when she sees your maintenance uniform[otherwise][The attendant] notices you but says nothing[end if].

You notice that your shadow has disappeared. That should make it easier to grab the Rose.";
			now the shadow is nowhere instead;
	otherwise:
		if the maintenance uniform is not worn by the player:
			say "[The attendant] looks over sharply. 'Leave those alone, you wretched man! That's for railroad maintenance only!'" instead;
		otherwise:
			now the shades are not drawn;
			now the shadow is part of Rodney Playfair;
			say "You pull up the shades. [if the maintenance uniform is not greeted][The attendant] says, 'Leave those alone, you--' but cuts off when she sees your maintenance uniform[otherwise][The attendant] notices you but says nothing[end if].

You notice that your shadow has returned." instead;

Before taking the Gavinchian Rose:
	if the Gavinchian Rose is carried by the player:
		say "There's no need to take what is already yours." instead;
	otherwise if in darkness:
		say "Surely Ms. Hogg would feel you trying to find the Rose in the dark. Better to wait for the light!" instead;

Before taking the Gavinchian Rose:
	if the shades are not drawn:
		say "Cornelia Hogg looks up as your shadow falls over her pages. She swats your hand away. 'What is this impertinence?' she demands. 

'Impertinence!' cries Horus. You back away, and Cornelia resumes her labors.";
		offend the parrot;
		warn of watchers instead;

[add opening shades]

Section 2 - Taste

A person can be thirsty or not thirsty. A person is usually thirsty.

Before taking the Gavinchian Rose:
	if Cornelia Hogg is thirsty:
		say "You reach for the rose, but Cornelia smacks her lips a bit and looks up. You only barely hide the tweezers in time.

'I'm parched,' she mutters. 'Simply parched[if the server is in observation car].' She looks at the server pointedly, but he ignores her, and she returns to her work.[otherwise]. Where is that server?'[end if]";
		warn of watchers instead;

The hidden bucket is a closed openable scenery container in Observation Car. The description of the hidden bucket is "[if the turn count > 10]Yes, that has been there all along. But it's not important.[otherwise]Strange you would look for that so soon.[end if]";

Understand "lid" as the hidden bucket.

Instead of opening the hidden bucket:
	say "That would attract unnecessary attention. The bucket radiates a sense of unimportance."

A thing can be grapeful or not grapeful. A thing is usually not grapeful.
The glass of grape juice is grapeful. The grape soda is grapeful.

Instead of giving a beverage to Cornelia Hogg:
	if the waiter costume is worn by the player:
		if the noun is grapeful:
			now Cornelia Hogg is not thirsty;
			say "Cornelia Hogg accepts the juice graciously, chugs it in one gulp, opens the lid of a bucket at her feet and smashes the glass into it before covering it again[if the noun is the grape soda].

She lets out an almighty belch as well[end if].

She seems less restless now. That should make it easier to grab the Rose.";
			now the noun is nowhere;
			now the glass of grape juice is on the tray full of drinks;
		otherwise:
			say "'Bah, I can't abide [if the noun is the glass of vodka]vodka[otherwise if the noun is the glass of soda]soda[otherwise if the noun is the glass of water]plain water[otherwise]these bizarre mixed drinks[end if]. Get me some good old juice!' she says.";
	otherwise:
		say "[The attendant] snaps at you. 'Let the servants attend to Ms. Hogg, sir.'

Hogg murmurs, 'If only you weren't such a ninny.' [The attendant] flushes.";

Instead of giving a beverage to the Viscount:
	if the noun is mixed:
		say "The Viscount observes your strange concoction with distaste and shakes his head.";
	otherwise if the noun is the glass of soda:
		say "The Viscount says, 'No thanks, it makes me gassy.'";
	otherwise if the noun is the glass of grape juice:
		say "'No thank you, too sweet for me,' says the Viscount.";
	otherwise if the noun is the glass of vodka:
		say "The Viscount scoffs. 'Such a harsh drink. Like drinking paint thinner.'";
	otherwise:
		say "The Viscount shakes his head. 'Thanks for asking, but no thank you.'";

Instead of giving a beverage to the parrot:
	if the noun is mixed:
		say "Horus stares at your mixed beverage in unmitigated horror.";
	otherwise if the noun is the glass of soda:
		say "Horus says, 'Squawk! Carbonation is harder for birds to process than humans! Squawk!'";
	otherwise if the noun is the glass of grape juice:
		say "Horus takes a quick peck at the juice.";
	otherwise if the noun is the glass of vodka:
		say "Horus's eyes gleam and he chuckles.

'No!' shouts Hogg. 'Bad Horus!'";
	otherwise:
		say "Horus takes a little bit.";

[player smell]

Section 3 - Touch

The tweezers are a thing. The tweezers are in the grooming kit. The tweezers are plural-named. The description of the tweezers is "Excellent for delicate work."

Report taking the tweezers:
	say "Perfect! This should help keep Hogg from feeling you take the Rose."

Instead of squeezing the tweezers:
	say "They bend and flex marvelously.

[bracket]But you will use the tweezers automatically now that you are holding them.[close bracket]"

Tweezing is an action applying to one thing. Understand "tweeze [something]" or "pluck [something]" as tweezing.

Carry out tweezing:
	if the noun is the parrot:
		say "You pluck a loose feather. Horus looks substantially unchanged, although he emanates smugness at being served by a human.";
	otherwise:
		try taking the noun;

Withtaking is an action applying to two things.  Understand "take [something] with [something]" as withtaking. Understand "get [something] with [something]" as withtaking.

Carry out withtaking:
	if the second noun is not the tweezers:
		say "You can't grab anything with [the second noun].";
	otherwise:
		try tweezing the noun;

Understand "pouch" as the grooming kit.

The emery board is a thing. The emery board is in the grooming kit. The description of the emery board is "Useful for filing the talons of birds. Not as useful for anything else." Understand "file" as the emery board. Understand "emory" as the emery board.

The talons are a part of the parrot. The talons can be filed or unfiled. The talons are plural-named. The description of the talons is "Horus's talons [if the talons are unfiled]need filing[otherwise]are well-filed[end if]." Understand "nails" as the talons.

Filing is an action applying to one thing. Understand "file [something]" or "scrape [something]" or "groom [something]" as filing.

Does the player mean wearing the pet groomer costume:
	it is likely;

Carry out filing:
	if the noun is the talons:
		if the emery board is carried by the player:
			if the talons are unfiled:
				if the pet groomer costume is worn by the player:
					now the talons are filed;
					say "'If I may, your majesty,' you say to Horus. You file the talons of Horus with panache. Horus squawks contentedly.";
					if the parrot is offended:
						now the parrot is not offended;					
				otherwise:
					say "Cornelia Hogg shouts, 'What are you doing with Horus? Get away from there!'";
			otherwise:
				say "But they are already filed!";
		otherwise:
			say "You have nothing to file with.";
	otherwise if the noun is the parrot:
		say "Horus already looks pretty good[if the talons are unfiled], but you can file his talons[end if].";
	otherwise:
		say "[The noun] [do] not need grooming by you at this time.";
				

Understand "pet" or "transparent" or "plastic" or "small" as the grooming kit. The grooming kit is a transparent closed openable container. The grooming kit is carried by Cornelia Hogg. The description of the grooming kit is "This is a small, transparent plastic pouch."

[Have Horus drop tweezers, or in costume, or carried by attendant]

Before taking the Gavinchian Rose:
	if the tweezers are not carried by the player:
		say "You grab at the rose, but despite your most cautious efforts, your fingers brush Hogg's lapel.  She looks up  and says, 'Fresh!' before slapping you. She returns to her papers. 

'Fresh!' cries Horus. You'll need something more delicate to remove it with.";
		offend the parrot;
		warn of watchers instead;
	otherwise:
		say "You use the tweezers to grab for the rose.";

Understand "pick [something]" as taking.

Section 4 - Smell

Before taking the Gavinchian Rose:
	if a stinky costume is worn by the player:
		say "Cornelia Hogg recoils from you. 'What is that distasteful odor? It smells [smell of a random stinky costume worn by the player].'

'Distasteful odor!' cries Horus.";
		offend the parrot;
		warn of watchers instead;

Section 5 - Sound

[Get parrot to sing]
A thing can be musical or not musical. The parrot is not musical.

Before taking the Gavinchian Rose:
	if the parrot is not musical:
		say "The sounds of your (admittedly very quiet) footsteps jars Cornelia from her focus. 'Hush!' she says, and she glares at you.

'Hush!' cries Horus.";
		offend the parrot;
		warn of watchers instead;
		
Chapter 4 - Speech

Introductions is a quip. The target of introductions is Cornelia Hogg.

The preview of Introductions is "'Good afternoon, Ms. Hogg.'"

TargetResponse of Introductions is "[Introduction of a random costume worn by the player][introductionProc]"

To say introductionProc:
	let currentCostume be a random costume worn by the player;
	now currentCostume is introduced;

TargetSummary of Introductions is "You've already introduced yourself to Hogg in [the list of introduced costumes]."

Report examining the Gavinchian Rose:
	if the Gavinchian Rose is not carried by the player:
		deliver Beautiful;

Beautiful is a quip. The target of beautiful is Cornelia Hogg.

The preview of Beautiful is "'That's a lovely jewel you're wearing.'"

TargetResponse of Beautiful is "[if the Gavinchian Rose is enclosed by Hogg]'That's a lovely jewel you're wearing.'

'Oh, thank you,' says Hogg, clearly warming up to a favorite topic. 'My father had it cut from a gem he found in one of those temples in Asia. Locals were mad, of course, but he made it out quick. 

'I guard it with my life, I'll have you know. Every one of my senses is attuned to its defense. So many people have tried to take it over the years!' she laughs, shaking her head.[otherwise]This might not be the best time for that conversation.[end if]"

TargetSummary of Beautiful is "You asked Cornelia Hogg about the rose, and she described how carefully she guards it."

Part 3 - Attendant

Chapter 1 - Attendant Herself

The attendant is a woman in Station. "[if the player is in Observation Car][The attendant] bustles in and out of the room constantly, keeping everything tidy and giving you frequent sidelong glances.[otherwise if Greetings is MeihTarget]Cornelia Hogg's attendant, a tall and commanding woman, is blocking the entrance to the train.[otherwise][The attendant] is waiting for you.

'Come along, [Alias in row CurrentAlias of the Table of Aliases]. This way, please!' she says, indicating the entrance to the east.[end if]"

 Understand "Beatrice" or "foxtrot" or "woman" or "tall" or "commanding" as the attendant.

 The description of the attendant is "The attendant is a towering, stern woman with tightly pulled-back hair, a starched blouse, and a frock coat.[DescriptionChanger] A nametag says 'Beatrice Foxtrot.'

A stubborn woman, you've learned from experimentation, who never leaves Hogg's side. But her poor eyesight makes your use of costumes all the better."

The starched blouse is worn by the attendant. The description of the blouse is "A very clean and well-ironed blouse."

The frock coat is worn by the attendant. The description of the frock coat is "Long, brown, and very stylish."

The tightly pulled-back hair is part of the attendant. The description of the tightly pulled-back hair is "Not a grey hair in the bunch."

The nametag is worn by the attendant. The description of the nametag is "It says 'Beatrice Foxtrot'". Understand "name" or "tag" as the nametag.

Report examining the nametag:
	deliver Relatives;

To say DescriptionChanger:
	now the printed name of the attendant is "Beatrice";
	now the attendant is proper-named;

Chapter 2 - Speech

Greetings is a quip. The target of greetings is the attendant. The preview of greetings is "A small bow towards the attendant."

TargetResponse of greetings is "[greeting of a random costume worn by the player][greetingsProc]"

To say greetingsProc:
	let currentCostume be a random costume worn by the player;
	now currentCostume is greeted;

TargetSummary of greetings is "You've already introduced yourself to [the attendant] in [the list of greeted costumes]."

Relatives is a quip. The target of relatives is the attendant. The preview of relatives is "'Foxtrot. Are you related to the Foxtrots of the Foxtrot Institute?'"

TargetResponse of relatives is "'Foxtrot. Are you related to the Foxtrots of the Foxtrot Institute?'

Beatrice's eyes light up. 'Why yes, yes I am. In fact, Andrew Foxtrot is my grandfather's first cousin's son. I met him once at a family gathering. Don't remember much what he looked like. I have a terrible memory for faces. But I remember his outfit: a tailored wool suit and a shirt with a collar stiff enough to kill a groundhog with. Impressive man.'

A terrible memory for faces. That's a useful piece of information."

TargetSummary of relatives is "You discovered that Beatrice is distantly related to Andrew Foxtrot."

Part 4 - Parrot

Chapter 1 - Parrot Himself

A thing can be eaten or uneaten.

The parrot is a man in Observation Car. "Hogg's pet parrot Horus is clinging to his perch, his box of crackers nearby." The description of the parrot is "Horus is [if the number of uneaten crackers > 15]an underfed[otherwise if the number of uneaten crackers  > 10]a well-stuffed[otherwise]a grotesquely over-stuffed[end if], ornery-looking green parrot."

Understand "Horus" or "bird" as the parrot.

Poking is an action applying to one thing.  Understand "poke [something]" as poking.

Carry out poking:
	if the noun is the parrot:
		say "As you reach out your finger, everyone in the room turns to you at once. 

'No!' screams the attendant.

'Stop!' cries Hogg.

Horus looks on with gleaming eyes, watching the finger approach. Your poke lands.

Hogg leaps at you in absolute fury, punching you with nasty jab-right cross combination. [The attendant] clings to your back, repeatedly kneeing your kidney.

You are muscled out the room and down the hallway. [The attendant] throws open the door and Hogg tosses you violently from the train.

As the train rushes past your limp body, you can hear a faint voice:

'Never! Poke! The parrot!'";
		end the story saying "You'll be back, once your bones heal. But this is the end for now.";
	otherwise:
		say "Hmmm, this isn't a good time for poking."

Section 1 - Accessories

The perch is scenery in Observation Car. The description of the perch is "This elaborate perch is carved in the shape of a cobra and seems to have been covered in gold leaf once. Now, though, it is worn through and covered in bites, scratches and claw marks." Understand "gold" or "leaf" or "cobra" or "scratches" or "claw" or "mark" or "marks" or "scratch" or "elaborate" as the perch.

Chapter 2 - Parrot talk

Understand "pet [something]" or "pat [something]" as rubbing.

Before rubbing:
	if the noun is the parrot:
		say "Horus bestows upon you the honor of petting him." instead;

Before touching:
	if the noun is the parrot:
		say "Horus bestows upon you the honor of petting him." instead;

Before kissing:
	if the noun is the parrot:
		say "Horus squawks at the indignity." instead;

[Hello]

Hello is a quip. The preview of Hello is "'Hello, pretty boy!'"

TargetResponse of Hello is "'Hello, pretty boy!' you say. 'How are we today?'[line break][ParrotGreeted]Horus [if the parrot is offended]peers at you suspiciously [otherwise]cocks his head at you [end if]and says, 'Hello! Hello! Horus demands a cracker!'"

TargetSummary of Hello is "Horus greeted you and asked for a cracker."

To say ParrotGreeted:
	deliver Snack;
	deliver Reject;
	say "[line break]";
[Snack]

Snack is a quip. The preview of Snack is "'Would you like a cracker?'"

Reject is a quip. The preview of Reject is "'No crackers for you, dear.'"

TargetResponse of Snack is "'Would you like a cracker, my feathered friend?' you ask.
[line break][ParrotSnacked]Horus bobs his head up and down, and says, 'Cracker! Horus will perform for a cracker.'"

TargetSummary of Snack is "Horus offered to perform for a cracker."

To say ParrotSnacked:
	deliver Performance;
	say "[line break]";
	
TargetResponse of Reject is "'No crackers for you, dear,' you say. 'Perhaps another time.'
[line break][ParrotSmacked][no line break]"

TargetSummary of Reject is "Horus was deeply offended."

[Performance]

Performance is a quip. The preview of Performance is "'Horus, will you perform for me?'"

TargetResponse of Performance is "'Horus my friend, will you perform for me?' you ask, crouching down to look Horus in the eye.
[line break][ParrotOptions]Horus says, 'Horus is blessed with an abundance of grace. Dance, music and rhetoric are all in my power.'"

TargetSummary of Performance is "Horus offered to sing, dance, or deliver a speech."

To say ParrotOptions:
	deliver Dance;
	deliver Music;
	deliver Rhetoric;
	say "[line break]";

[Dance]

Dance is a quip. The preview of Dance is "'Dance, Horus!'"

TargetResponse of Dance is "Horus squawks and hops from one foot to the other.[ParrotDance]"

To say ParrotDance:
	do nothing;

TargetSummary of Dance is "Horus danced for you."

[Music]

Music is a quip. The preview of Music is "'Sing for me?'"

TargetResponse of Music is "[ParrotSing]Horus stretches tall and begins to sing a bespoke adaptation of The Charge of the Light Brigade. It seems it will go on for quite some time.

Wonderful. That should help mask the sound of your footsteps when you take the Rose."

TargetSummary of Music is "Horus is still singing. He seems quite proud of himself!"

To say ParrotSing:
	now the parrot is musical;
	the musicing ceases in three turns from now;
	
At the time when the musicing ceases:
	say "Horus stops singing and preens his feathers. He seems eager to sing again.";
	now Music is not TargetGiven;
	now the parrot is not musical;
	say "[line break][bracket]Renewed topic for the parrot - [bold type]Music[roman type][close bracket][line break]";

Every turn:
	if the parrot is musical:
		say "Horus is currently singing at the top of his lungs[if the parrot is offended], but he's glaring at you while he does it[end if].";

[Rhetoric]
Rhetoric is a quip. The preview of Rhetoric is "'Speech! Speech!'"

TargetResponse of Rhetoric is "Horus [if the parrot is musical]stops singing and [end if]strikes a majestic pose and says, [one of]'A word once uttered can never be recalled!'[or]'Good health and good sense are two of life's greatest blessings!'[or]'The only certainty is that nothing is certain!'[or]'Young men, hear an old man to whom old men hearkened when he was young!'[or]'Say not always what you know, but always know what you say!'[or]'Fortune favors the brave!'[or]'The drops of rain make a hole in the stone, not by violence, but by oft falling.'[at random]"

Report speeching Rhetoric to the parrot:
	if the parrot is musical:
		now Music is not TargetGiven;
		now the parrot is not musical;
		say "Horus might be willing to finish his interrupted song.

[bracket]Renewed topic for the parrot - [bold type]Music[roman type][close bracket][line break]";

TargetSummary of Rhetoric is "Horus gave you a quotation."

Destroy is a quip. The preview of Destroy is "'Horus, Destroy!'"

TargetResponse of Destroy is "[parrotrelease]"

TargetSummary of Destroy is "You unleashed the power of the parrot!"

To say parrotrelease:
	unleash the parrot;


Chapter 3 - Progress

Section 1 - Basics

A person can be offended or not offended. A person is usually not offended.

To say ParrotSmacked:
	offend the parrot;
		
Before speeching something to the parrot:
	if the parrot is offended:
		say "Horus seems upset with something you did earlier. Seems he's a sensitive soul[one of][or][or][or].

He squawks at Hogg and looks pointedly at his box of crackers, but she doesn't seem to hear him[cycling]." instead;

Section 3 - Decreasing Suspicion

Instead of eating a cracker:
	say "Horus looks horrified.";
	now the noun is nowhere;

A cracker is a kind of thing. The description of a cracker is usually "Some things in life are useful, lovely, well-renowned, or praiseworthy. This is none of those things. It is a cracker. For parrots."


The box of crackers is scenery in Observation Car. The box of crackers is an open openable container. In the box of crackers are 5 crackers. 

The examine containers rule does nothing when examining the box of crackers.

The secret stash of crackers is a room. In the secret stash of crackers are 15 crackers.

The description of the box of crackers is "A box of surprisingly tasty-looking crackers[if the number of crackers in the box of crackers is 0]. At least, it was[end if]. You can see [number of crackers in the box of crackers in words] cracker[s] inside[if the number of crackers in the secret stash of crackers > 0], but there are probably more[end if]."

Instead of taking the box of crackers:
	say "Horus squawks and pecks at you. Looks like the box is staying there."

Every turn:
	if the number of crackers in the box of crackers < 5:
		if the number of crackers in the secret stash of crackers > 0:
			repeat with current running through crackers in the secret stash of crackers:
				if the number of crackers in the box of crackers < 5:
					now current is in the box of crackers;

Instead of giving a cracker to the parrot:
	if the number of uneaten crackers is 1:
		say "Horus gobbles down the cracker and explodes in a cloud of feathers and cracker bits, destroying you, the car, its passengers, and the Gavinchian Rose.";
		end the story saying "You have failed.";
	otherwise:
		say "Horus gobbles the cracker greedily, swallows, and lets out a happy belch.";
		now the noun is nowhere;
		now the noun is eaten;
		if the parrot is offended:
			now the parrot is not offended;

Instead of giving a cracker to the attendant:
	say "'No thanks, I find them rather dry,' she says. 'And Horus gets terribly jealous.'"

Instead of giving a cracker to Cornelia Hogg:
	say "Cornelia Hogg says, 'Thanks.' She then flicks the cracker expertly across the room, and Horus catches it in his mouth.";
	now the noun is nowhere;
	now the noun is eaten;
	
Instead of giving a cracker to Viscount:
	say "The Viscount stares at you with a completely blank expression. You slowly lower the cracker.";
	
Instead of giving a cracker to the server:
	say "'You insult me, sir,' he says gloomily."

Instead of inserting a cracker into the tray of drinks:
	say "The server dodges you, trying to avoid extra clutter."

Instead of putting a cracker on the tray of drinks:
	say "The server dodges you, trying to avoid extra clutter."

Section 4 - Reporting Suspicion

To offend the parrot:
	if the parrot is not offended:
		say "[line break]Horus is deeply offended by your suspicious actions. He's glaring at you. A peace offering or two might be in order.";
		now the parrot is offended;
	otherwise:
		say "[line break]Horus is aghast at your continued effrontery."
		
Part 5 - The Viscount

[Menu conversation with Viscount? Point out absurdity of sunglasses]

Chapter 1 - The Viscount Himself

The Viscount is a man in Observation Car. "The Viscount has been pretending to read the same magazine page for the last [one of]thirty[or][RunningTime][stopping] minutes."The description of the Viscount is "The Viscount is a perennial passenger in Hogg's observation car, although he never seems to speak. He is wearing [a list of things worn by Viscount]. You could recognize him from his pungent odor alone, though.

The Viscount is clearly wearing a disguise, but no one else has noticed[if the number of things worn by Viscount < 3], despite the fact that you've removed some of it[end if]. Telling the others might bring attention to your own disguise, but [if the number of things worn by Viscount < 3]removing the rest of his disguise[otherwise]revealing the Viscount's deception[end if] could get him out of your hair."

Understand "count" or "vis" as the Viscount.

To say RunningTime:
	let x be the turn count plus 30;
	say "[x in words]";

To warn of watchers:
	if viscount is in Observation Car:
		say "[line break]You can feel the Viscount's eyes on you. You won't be able to take the rose with him watching, either."

Chapter 2 - The Viscount's disguise

The wide hat is worn by the Viscount. The description of the wide hat is "The Viscount's wide-brimmed hat is huge and messy, like a mouse's nest. Perfect for obfuscation."

Understand "wide-brimmed" or "brim" as the wide hat.

A heavy scarf is worn by the Viscount.  The description of the heavy scarf is "The Viscount's heavy woolen scarf is unusually bulky and hot-looking. Perfect for obfuscation."

Understand "woolen" or "bulky" as the heavy scarf.

A fake beard is worn by the Viscount. The description of the fake beard is "The Viscount's heavy beard is impressive, but a trained professional like you can easily tell it's attached with spirit gum. The right solvent could wipe it right off."

Instead of pulling the fake beard:
	say "You feel a little give and the Viscount grimaces, but it snaps back when you let go. Some kind of adhesive? The Viscount glares at you."

Instead of rubbing the fake beard:
	say "That's altogether too obvious. The Viscount slaps your hand away."

Understand "bushy" or "spirit" or "gum" as the fake beard.

[Have a hidden thing here that is ridiculous as a disguise--maybe a mask?]

Instead of taking the wide hat:
	say "The Viscount slaps your hand away as soon as you start tugging."

Chapter 3 - Progress

Section 1 - The scarf

The observation car can be toasty or not toasty. The observation car is not toasty.

The radiator is scenery in Observation Car. The description of the radiator is "The radiator provides heat to the car with steam power. It has a small knob that can be turned to increase or decrease the temperature."

The small knob is part of the radiator. The description of the small knob is "This knob controls the temperature. You can turn it to make it hotter or colder." Understand "valve" as the small knob. Understand "heater" as the radiator. Understand "radiator knob" or "dial" as the small knob.

Instead of touching the radiator:
	if the observation car is toasty:
		say "By your grandmother's sister's pet ferret, that is hot!";
	otherwise:
		say "It's not hot right now. Either that, or so hot it seared off the nerves in your fingertips. Probably the first."

Before turning the radiator:
	try turning the small knob instead;

Upturning is an action applying to one thing. Understand "turn up/down [something]" as upturning.

Carry out upturning:
	if the noun is the small knob:
		try turning the small knob;
	otherwise if the noun is the radiator:
		try turning the small knob;
	otherwise:
		say "That's not an interaction that I know how to handle.";

Instead of opening the radiator: try turning the small knob

Instead of closing the radiator: try turning the small knob

Instead of switching off the radiator: try turning the small knob

Instead of switching on the radiator: try turning the small knob

The Viscount can be necky or not necky. The Viscount is not necky. Understand the necky property as describing the Viscount. Understand "short" or "tanned" or "neck" as the necky.

Instead of turning the small knob:
	if the maintenance uniform is not worn by the player:
		say "[The attendant] looks over sharply. 'Leave that alone, you wretched man! That's for railroad employees only!'" instead;
	otherwise if the observation car is toasty:
		now the observation car is not toasty;
		say "You turn the knob, cooling off the observation car.";
	otherwise:
		now the observation car is toasty;
		say "You turn the knob, heating up the observation car significantly. ";
		if the heavy scarf is worn by the Viscount:
			now the heavy scarf is nowhere;
			say "[paragraph break]The Viscount is sweating profusely. He unwinds the heavy scarf and stows it away out of sight, revealing a short, tanned neck. 

'Awful hot, isn't it?' says the Viscount.";
			now the Viscount is necky;
			ViscountReact;

When play begins:
	the radiator hisses in four turns from now;

At the time when the radiator hisses:
	if the observation car is not toasty:
		if the player is in Observation Car:
			say "The radiator rattles and hisses.";
	the radiator hisses in four turns from now;
	
Instead of taking the heavy scarf:
	say "The Viscount slaps your hand away with a rolled-up magazine, then unfolds it and continues reading."

Section 2 - The beard

The magazine is carried by the Viscount. The description of the magazine is "[italic type]Vogue[roman type]. This week's."

Understand "vogue" as the magazine.

Instead of taking the fake beard:
	say "The Viscount slaps your hand away with a rolled-up magazine, then unfolds it and continues reading."
	
Instead of putting the glass of vodka on someone:
	try throwing the glass of vodka at the second noun;

Instead of throwing the glass of vodka at the fake beard:
	try putting the glass of vodka on the fake beard;

Instead of throwing the glass of vodka at the Viscount:
	if the fake beard is worn by the Viscount:
		try putting the glass of vodka on the fake beard;
	otherwise:
		say "Haven't you already tried something like this?";

Instead of putting a beverage on the fake beard:
	if the noun is the glass of vodka:
		say "The Viscount jumps to his feet, spluttering and gasping, but the spirit gum dissolves in the vodka and the beard falls to the floor. 'Oh my, I do apologize,' you say, 'How clumsy of me!'

	'You wretch!' he hisses. There's murder in his eyes.

	[The attendant] says, 'What in the world are you two doing?' She marches closer, snatching up the beard, but Cornelia Hogg, without looking, says, 'Beatrice! Don't be such a busybody.' [The attendant] stops, fuming.

	[if the server is not in observation car]The server makes an appearance, grabs the glass, and exits.[otherwise]The server grabs the glass of vodka and departs.[end if]";
		now the server is nowhere;
		now the glass of vodka is in the tray of drinks;
		now the fake beard is nowhere;
		ViscountReact;
	otherwise:
		if the noun is vodkamixed:
			say "After some thought, [the noun] won't really do anything to the fake beard. At least, not enough. You'd need a higher proof solvent.";
		otherwise:
			say "After some thought, [the noun] won't really do anything to the fake beard. You'd need a better solvent, like rubbing alcohol or spirit gum remover."

Pouring it on is an action applying to two things. Understand "pour [something] on [something]" or "spill [something] on [something]" as pouring it on. Understand "wipe [something] with [something]" as pouring it on (with nouns reversed).

Carry out pouring it on:
	if the noun is not a beverage:
		say "That's not something you can pour.";
	otherwise if the second noun is not the fake beard:
		say "[if the second noun is the Viscount]Perhaps you should specify what part of the Viscount you are pouring it on. There's a lot of Viscount to work with.[otherwise if the second noun is the player]You pour a small amount of [the noun] on yourself. Everyone stops what they're doing and stares at you, too afraid to comment on your bizarre behavior.[otherwise if the second noun is Cornelia Hogg][The attendant] gives you a vicious glare. You think better of it.[otherwise if the second noun is the attendant][The attendant] watches as you gradually approach closer and closer, gently tipping [the noun] towards her. You both stare, mesmerized, as a single drop of liquid beads on the edge of the glass, ready to spill onto her. Sweat trails from your brow. Her eyes blaze with fascination.

Then Hogg coughs; you both look, and the spell is broken. You don't have the nerve. You back away from [the attendant]. She watches you, wistful.[otherwise if the second noun is the parrot]You dangle [the noun] over Horus's head, cackling internally. Horus pecks at your hand, and you spill a bit on yourself. You retreat.[otherwise if the second noun is the server]The server says simply, 'No.'[otherwise if the second noun is worn by the Viscount]You pour a tiny drop of liquid on [the second noun]. The Viscount doesn't notice you, but nothing interesting happens, either.[otherwise if the second noun is worn by a person]No matter how you try, you can't get close enough without drawing attention from [the attendant].[otherwise]You very gently spill one drop of [the noun] on [the second noun]. Nothing interesting happens.[end if]";
	otherwise if the noun is the vodka water:
		say "That would work perfectly, if it weren't so diluted.";
	otherwise if the noun is not the glass of vodka:
		if the noun is vodkamixed:
			say "After some thought, [the noun] won't really do anything to the fake beard. At least, not enough. You'd need a higher proof solvent.";
		otherwise:
			say "After some thought, [the noun] won't really do anything to the fake beard. You'd need a better solvent, like rubbing alcohol or spirit gum remover.";
	otherwise:
		try putting the glass of vodka on the fake beard;
	
Section 3 - The Wide Hat

Before opening the grooming kit:
	if the grooming kit is carried by Cornelia Hogg:
		say "That'd be difficult to do discreetly." instead;

The toy mouse is in the grooming kit. The description of the toy mouse is "This is a soft, plush toy mouse covered in claw marks." Understand "soft" or "plush" as the toy mouse.

Before inserting something into a beverage:
	if the noun is not a beverage:
		say "You've been trying to kick your habit of putting random objects into liquids." instead;

Instead of waving the toy mouse:
	say "Horus follows your movements eagerly."

Instead of giving the toy mouse to the parrot:
	say "He looks at the mouse and then at you expectantly. Maybe he doesn't want it given to him directly?"

After taking the toy mouse:
	if Destroy is not carried by the player:
		say "You grab the mouse. Horus perks up. 'The enemy! Send me forth to destroy the foul creature!'";
		deliver Destroy;
	otherwise if Destroy is targetgiven:
		now Destroy is not TargetGiven;
		say "You grab the mouse. Horus seems eager to play again.

[bracket]Renewed topic for the parrot - [bold type]Destroy[roman type][close bracket][line break]";
	otherwise:
		say "Taken.";

Before taking the toy mouse:
	if the toy mouse is on the wide hat:
		say "Taken.";
		now the toy mouse is carried by the player instead;

Every turn:
	if the toy mouse is carried by the player:
		deliver Destroy;

Instead of showing the toy mouse to the parrot:
	say "Horus shrieks. 'Call on Horus, and he shall destroy!'";
	deliver Destroy;
	
To unleash the parrot:
	if the toy mouse is on the wide hat:
		say "Horus leaps into the air and descends on the Viscount with a screech.

The Viscount ducks, but Horus snags the mouse (and the hat) with his claws.  He attacks until both are in shreds while the Viscount cries, 'Off! Off!'

[The attendant] shouts, 'Horus! Get away from there!'

Hogg says, 'Now, now, Beatrice, Horus needs his bit of fun. You don't need to carry on.'

[The attendant] sighs and gathers up the mouse and shreds of hat, giving the Viscount a strange look as she does so.";
		now the toy mouse is nowhere;
		now the wide hat is nowhere;
		ViscountReact;
	otherwise if the toy mouse is enclosed by a container:
		say "Horus hops from foot to foot, confused.";		
	otherwise:
		say "Horus leaps to the toy mouse and savages it before flying to his roost and dropping the mouse to the ground.";
		now the toy mouse is in Observation Car;

[check what we put on the hat]

The wide hat is a supporter;

Instead of inserting the toy mouse into something:
	try putting the toy mouse on the second noun;

Instead of throwing the toy mouse at the Viscount:
	if the toy mouse is not carried by the player:
		say "But you're not holding the toy mouse!";
	otherwise:
		say "The mouse hits the Viscount's body and falls to the ground. The Viscount ignores it completely.";

Instead of throwing the toy mouse at the wide hat:
	if the toy mouse is not carried by the player:
		say "But you're not holding the toy mouse!";
	otherwise:
		say "You make a toss. The mouse lands on top of the Viscount's hat!";
		now the toy mouse is on the wide hat;
	
Instead of putting the toy mouse on the wide hat:
	if the toy mouse is not carried by the player:
		say "But you're not holding the toy mouse!";
	otherwise:
		say "You sidle up behind the Viscount and place the mouse on his hat before gliding away.";
		now the toy mouse is on the wide hat;

Instead of putting the toy mouse on the heavy scarf:
	if the toy mouse is not carried by the player:
		say "But you're not holding the toy mouse!";
	otherwise:
		say "The scarf is wrapped quite firmly, leaving little room to place a mouse. But using the mouse seems like a good idea in general.";

Instead of putting the toy mouse on the Gavinchian Rose:
	if the toy mouse is not carried by the player:
		say "But you're not holding the toy mouse!";
	otherwise:
		say "You can see it all in your mind. The mouse, placed on the Rose. The owl, soaring through the air to grab the rose, bringing it back to you while you stand there, grinning. Yes...yes...yes! A genius plan!

Then you realize that if you could get close enough to place the rose, you could just as well take it.";

Instead of putting the toy mouse on the fake beard:
	if the toy mouse is not carried by the player:
		say "But you're not holding the toy mouse!";
	otherwise:
		say "The beard is in front of the Viscount, making it difficult to put anything in it unnoticed.";

Instead of putting the toy mouse on the Viscount:
	if the toy mouse is not carried by the player:
		say "But you're not holding the toy mouse!";
	otherwise:
		say "There's a lot of Viscount to work with. What part will you put it on?";

Instead of throwing the toy mouse at the Viscount:
	if the toy mouse is not carried by the player:
		say "But you're not holding the toy mouse!";
	otherwise:
		say "You make a toss. The mouse lands on top of the Viscount's hat!";
		now the toy mouse is on the wide hat;

Before putting a cracker on the wide hat:
	say "Horus squawks in panic at the loss of a precious cracker. The Viscount looks up, glares at you, and scoots away." instead;

[check putting the mouse on the gavinchian rose, scarf, and beard]

Before putting the suitcase on the wide hat:
	say "The entirety of your plan rides on this suitcase. Putting it on the hat, while amusing, would be fairly foolish, and the Magpie is never foolish." instead;

Before putting a beverage on the wide hat:
	say "You catch [the attendant] watching you with a shocked expression, so you back away." instead;

Chapter 4 - Finale of Viscount

Before taking the Gavinchian Rose:
	if the Viscount is in Observation Car:
		say "The Viscount coughs loudly as you approach Hogg, and Hogg looks around the room, forcing you to withdraw.

Horus says, 'Caught! Caught!'";
		offend the parrot instead;

To ViscountReact:
	say "[line break]";
	if the number of things worn by Viscount is 0:
		if the Viscount is in Observation Car:
			say "Now that you can see him more clearly, you recognize the so-called Viscount.  It appears [the attendant] recognizes the figure before you as well.

'Good heavens, it's Elizabeth Russell, the jewel thief! And what's worse,' she shouts, 'She was wearing a [italic type]costume[roman type].' Hogg looks up, aghast, and Horus screeches. 'Villain! Thief! Forger!' [The attendant] advances menacingly.

Elizabeth starts to her feet. 'Yes, I am Elizabeth Russell. And never have I been treated so poorly in my life! Attacked by this foul bird, covered in cheap spirits, almost overcome by heat, and especially pestered by this man!' she says, pointing at you. 'When I steal from my marks, I expect luxury and comfort. Well, there's no luxury or comfort here!' she shouts before running out of the room to the south, slamming the door behind her.

There is a clang from the outer door opening, followed by a thud and rolling sound that quickly grows distant.

[The attendant] huffs, saying, 'And I specifically said that disguises are prohibited. The cheek!'";
			now the Viscount is nowhere;
	otherwise if the number of things worn by Viscount is 1:
		say "The Viscount is distressed, and crams himself into the darkest corner of his seat.";
	otherwise:
		say "The Viscount retreats from you towards the wall and attempts to be less conspicuous.";

Chapter 5 - Viscount speech

Familiar is a quip. The target of Familiar is Viscount. The preview of Familiar is "'You seem familiar, sir. Have we met?'"

TargetResponse of Familiar is "[The familiarity of a random costume worn by the player][familiarProc]"

To say familiarProc:
	let currentCostume be a random costume worn by the player;
	now currentCostume is familiarized;
	
Understand "upton" or "snodsbury" as the viscount.

TargetSummary of Familiar is "The Viscount denied any acquaintance with you."

Fashion is a quip. The target of Fashion is Viscount. The preview of Fashion is "'Anything interesting in fashion this season?'"

TargetResponse of Fashion is "'Anything interesting in fashion this season?'

'What?' asks the Viscount.

You point at the magazine. 'You seem interested. What sort of things are fashionable this year? One must keep up with these things, you know, however tedious it may be.'

[if the heavy scarf is worn by the Viscount]The Viscount laughs hesitantly, fingering the heavy scarf around his neck. 'Scarves are the fashion this year,' he says.[otherwise]The Viscount scowls at you, touching his bare neck. 'Scarves were the trending fashion this year'.[end if]"

Report examining the magazine:
	deliver Fashion;

Part 6 - The server

Chapter 1 - The server himself

The server is a man. "A server holding a tray of drinks is standing sulkily in the car."

The description of the server is "The server is a dour and shaggy-headed young man bearing a tray full of drinks." 

Understand "dour" or "shaggy" or "shaggy-headed" or "young man" as the server.

The tray full of drinks is a container carried by the server. The description of the tray full of drinks is "This tray contains complimentary drinks, a grudging concession towards hospitality by the usually stingy Hogg."

The printed name of the tray full of drinks is "[if the number of things enclosed by the tray full of drinks is 0]empty tray[otherwise]tray full of drinks[end if]"

Understand "drink" as the tray of drinks.

Instead of taking the tray of drinks:
	say "The tray has [a list of beverages enclosed by the tray of drinks] on it."

A beverage is a kind of thing. The glass of water is a beverage. The glass of soda is a beverage. The glass of vodka is a beverage. The glass of grape juice is a beverage.

Understand "serve [a beverage] to [someone]" as giving it to.

Instead of inserting a beverage into the grooming kit:
	say "That doesn't seem very reasonable."
	
Instead of inserting the suitcase into the grooming kit:
	say "While this is topologically possible, its not physically realizable."

[Merging is an action applying to two things. Understand "mix [something] with/and [something]" or "pour [something] in/into [something]" as merging. Understand "combine [something] with/and [something]" as merging.

Carry out merging:
	if the second noun is the fake beard:
		say "Did you mean pouring [the noun] on the fake beard?";
	otherwise:
		say "It's too risky. And you feel confident you can get by without it."]

The description of the glass of water is "A classic beverage, if rather unappealing."
The description of the glass of soda is "A seltzer, plain."
The description of the glass of vodka is "A strong drink. This is strong enough to strip paint off!"
The description of the glass of grape juice is "A deep purple liquid fills the glass."

[This server code could cause problems]

Instead of drinking a beverage:
	if the noun is the glass of vodka:
		say "One sniff sends your head in a whirl, and not in a good way. This is very cheap vodka, almost like rubbing alcohol. You'd never drink this.";
	otherwise if the noun is the grape soda:
		say "Ahh, that's very refreshing! The server has your glass before you can even blink, then returns to his original location.";
		now the noun is nowhere;
	otherwise if the noun is a mixed beverage:
		say "Your mixture doesn't seem very appealing. Your cultured palate refuses to try it.";
	otherwise:
		say "You drink [the noun][if in darkness]. You hear the server take the glass.[otherwise if the server is in Observation Car].  The server grabs the glass and disappears through the door.[otherwise]. The server pops in his head, grabs the glass, and takes it out the door.[end if]";
		now the server is nowhere;
		now the noun is in the tray of drinks;

The glass of water is in the tray full of drinks. The glass of soda is in the tray full of drinks. The glass of vodka is in the tray full of drinks. The glass of grape juice is in the tray full of drinks.

Before taking a beverage:
	if the noun is in the tray full of drinks:
		say "You grab [the noun] from the server's tray. He grunts in acknowledgment and continues to stare at the floor.";
		now the noun is carried by the player instead;

Combining it with is an action applying to two things. Understand "pour [a beverage] in/into [a beverage]" or "mix [a beverage] with/into/and [a beverage]" or "combine [a beverage] with/and [a beverage]" as combining it with. 

A beverage can be mixed or unmixed. A beverage is usually unmixed.

A beverage can be vodkamixed or vodkaunmixed. A beverage is usually vodkaunmixed.

Carry out combining it with:
	if the noun is mixed:
		if the second noun is the noun:
			say "You slosh around [the noun] in its own glass. It does not look improved by this action.";
		otherwise:
			say "There's not enough room in either glass to hold the whole drink, so you end up spilling it everywhere. Hogg clucks at you in distaste and [the attendant] politely but firmly escorts you from the room.";
			end the story saying "You tried your best but your results were mixed";
	otherwise if the second noun is mixed:
		say "There's not enough room in either glass to hold the whole drink, so you end up spilling it everywhere. Hogg clucks at you in distaste and [the attendant] politely but firmly escorts you from the room.";
		end the story saying "You tried your best but your results were mixed";
	otherwise:
		say "You pour [the noun] into [the second noun]. Everyone in the car watches you as you do it. It's quite loud[if the server is in Observation car]. The server takes the empty glass and steps outside to refill the tray, before returning[otherwise]. The server pops in to take the empty cup and leaves again[end if].";
		now the noun is on the tray full of drinks;
		now the second noun is on the tray full of drinks;
		say "[conditional paragraph break]";
		if the noun is the glass of water:
			if the second noun is the glass of soda:
				say "You've successfully created a watery seltzer. This has absolutely no uses.";
				now the watery seltzer is carried by the player;
			if the second noun is the glass of grape juice:
				say "You've successfully created grape water. This has absolutely no uses.";
				now the grape water is carried by the player;
			if the second noun is the glass of vodka:
				say "You've successfully created vodka water. This has absolutely no uses.";
				now the vodka water is carried by the player;
			if the second noun is the glass of water:
				say "You slosh the water around in its own glass. It is uninspiring.";
		otherwise if the noun is the glass of soda:			
			if the second noun is the glass of water:
				say "You've successfully created a watery seltzer. This has absolutely no uses.";
				now the watery seltzer is carried by the player;
			if the second noun is the glass of grape juice:
				say "You've successfully created grape soda. This is actually pretty good.";
				now the grape soda is carried by the player;
			if the second noun is the glass of vodka:
				say "You've successfully created sparkling vodka. If it weren't for the cheap and frankly disgusting vodka used, it might be interesting. But it's not.";
				now the sparkling vodka is carried by the player;
			if the second noun is the glass of soda:
				say "You slosh the soda around in its own glass. It is uninspiring.";
		otherwise if the noun is the glass of grape juice:			
			if the second noun is the glass of water:
				say "You've successfully created grape water. This has absolutely no uses.";
				now the grape water is carried by the player;
			if the second noun is the glass of soda:
				say "You've successfully created grape soda. This is actually pretty good.";
				now the grape soda is carried by the player;
			if the second noun is the glass of vodka:
				say "You've made a kind of martini, if martinis were terrible. This is useless.";
				now the martini is carried by the player;
			if the second noun is the glass of grape juice:
				say "You slosh the grape juice around in its own glass. It is uninspiring.";
		otherwise:
			if the second noun is the glass of water:
				say "You've successfully created vodka water. This has absolutely no uses.";
				now the vodka water is carried by the player;
			if the second noun is the glass of soda:
				say "You've successfully created sparkling vodka. If it weren't for the cheap and frankly disgusting vodka used, it might be interesting. But it's not.";
				now the sparkling vodka is carried by the player;
			if the second noun is the glass of grape juice:
				say "You've made a kind of martini, if martinis were terrible. This is useless.";
				now the martini is carried by the player;
			if the second noun is the glass of vodka:
				say "You slosh the vodka around in its own glass. It is uninspiring.";


The watery seltzer is a mixed beverage. The description of the water seltzer is "The result of a disappointing experiment."
The grape water is a mixed beverage. The description of the water seltzer is "The result of a disappointing experiment."
The vodka water is a vodkamixed  mixed beverage. The description of the water seltzer is "The result of a disappointing experiment."

The grape soda is a mixed beverage. The description of the grape soda is "Actually pretty good."
The sparkling vodka is vodkamixed mixed beverage. The description of the sparkling vodka is "Completely terrible."

The disappointing martini is a vodkamixed mixed beverage. The description of the disappointing martini is "One of the worst things you've ever made."

Instead of inserting a beverage into a beverage:
	try combining the noun with the second noun;

Chapter 2 - The server's behavior

FirstFlag is a number that varies. FirstFlag is 0.

Every turn:
	if the player is in Observation Car:
		if FirstFlag is 0:
			the server arrives in three turns from now;
			now FirstFlag is 1;
	
At the time when the server arrives:
	if in darkness:
		if the player is in Observation Car:
			now the server is in Observation Car;
			say "You can hear the server stomping into the room, carrying a tray of drinks, although you cannot see him.";
	otherwise if the player is in Observation Car:
		now the server is in Observation Car;
		say "The server stalks in, [first time]punctual as usual, and [only]carrying his tray of drinks. He stands, slouched, staring at the floor, waiting for someone to grab a beverage. You can see quite a few drinks on the tray[if Cornelia Hogg is thirsty]. Cornelia smacks her lips, glancing at the tray of drinks but not stopping her work or concentration[end if][if the waiter costume is worn by the player].

[WaiterText][end if].";
	the server departs in two turns from now;
	the window incident occurs in one turn from now;
		
To say WaiterText:
	say "[one of]He looks your waiter costume up and down. He doesn't say anything, but his expression is clear. 'Another mixup by the coordinator,' it says. 'Well, it's not my fault.' His expression returns to its usual stoic silence[or]He looks at your costume again, shaking his head slightly[stopping]"

At the time when the window incident occurs:
	if the player is in Observation Car:
		if the shades are not drawn:
			if not in darkness:
				if a random chance of 1 in 2 succeeds:
					say "The server blinks in the bright sunlight streaming through the windows. He goes to pull the shades, but [the attendant] says, 'No, no, no, only authorized staff can close the shades.'";
	
At the time when the server departs:
	if the player is in Observation Car:
		if not in darkness:
			now the server is nowhere;
			say "The server stomps out of the room.";
			the server arrives in five turns from now;
		otherwise:
			the server departs in two turns from now;
	otherwise:
		the server departs in two turns from now;


Book 3 - Ending

After taking the Gavinchian rose:
	say "With your breath held, you delicately lift the Rose. Everything seems to pause. Then it's over, and you have it.

Finally! The Rose is yours! Now all that's left is to get out while you still can.";	

Instead of wearing the Gavinchian Rose:
	say "You might as well take your own mugshot as well. Let's not do that."

Before going outside from observation car:
	try going south instead;
	
Before exiting:
	try going outside instead;

Before going south from observation car:
	if the Gavinchian Rose is not carried by the player:
		say "Not without the Rose!" instead;
	otherwise if the feather is enclosed by the player:
		say "You're still carrying the feather. It would be a shame not to drop your calling card." instead;
	otherwise:
		say "[if in darkness]The train exits the tunnel and light returns to the car.

[end if]As you bow discreetly and make your exit, you are stopped by a squawk from Horus.

'Purloiner! Pincher! Poacher! Pickpocket!'

Cornelia Hogg finally looks up. 'Horus, what is the matter?' She looks at Beatrice. 'Is something going on?'

'Is something going on? You mean besides Horus destroying a hat, vodka spilled all over the car, the darkness, the heat, the weird smells? No, things are just fine, Miss Hogg. Just fine,' says the attendant, rolling her eyes. She looks at you distractedly. 'Have a nice day, sir,' she tells you.

'Yes, yes, have a nice day,' adds Hogg, going back to her papers.

'I assure you I will, madame.' And with that, you make your exit.";
		end the story finally instead;
		
Volume 2 - Mechanics

Book 1 - Responses and Rules

Part 1 - When play begins

When play begins:
	say "The Gavinchian Rose!  A priceless ruby that adorns the lapel of steel magnate Cornelia Hogg. For weeks you've followed the gem and observed its eccentric owner aboard her private rail car. But today is different. Today the Rose will finally be yours! 

You straighten your newest disguise and line up for the train. As is your custom, you're the last one to board.";


Part 2 - Standard Responses

Screaming is an action applying to nothing. Understand "scream" or "yell" as screaming.

Carry out screaming:
	say "'AAAAAAAAAAAAAAAAAGGGGGGGGGGGGGHHHHHHHHHHHH!' you quietly say under your breath."

 The block vaguely going rule response (A) is "There's nowhere for you to go until you get that gem."
 The can't take yourself rule response (A) is "You take yourself exactly as you are."
 The can't take other people rule response (A) is "You generally only take inanimate objects."
 The can't drop yourself rule response (A) is "Don't give up on yourself now!"
 The can't eat unless edible rule response (A) is "While you are adventurous in many ways, eating inedible objects is not one of them.".

 The examine undescribed things rule response (A) is "[The noun] is not helpful to you right now."
 The standard looking under rule response (A) is "You step back and discreetly peek under [the noun], but find nothing."
	The block showing rule response (A) is "[The second noun] pays no heed to [the noun]."
	The block throwing at rule response (A) is "Tempting, but no."
	The block attacking rule response (A) is "You're the Magpie, not the Hawk.".

	The kissing yourself rule response (A) is "It's awkward, but you manage it. [The attendant] is nonplussed."
	The block kissing rule response (A) is "A gentleman never takes liberties."

	The block answering rule response (A) is "[The noun] pays you no heed."

	The telling yourself rule response (A) is "You find your own conversation exciting and interesting, but now isn't the time to indulge in it."
	The block telling rule response (A) is "[The noun] pays you no heed."

	The block asking rule response (A) is "[The noun] pays you no heed."

	The standard report waiting rule response (A) is "You bide your time[one of]. 

[bracket]You can skip directly to the next time the train goes under the bridge by typing SKIP.[close bracket].[or].[or].[or].[or].[or].[or]. 

[bracket]You can skip directly to the next time the train goes under the bridge by typing SKIP.[close bracket].[or].[or].[or].[or].[or].[or].[stopping]"

	The report touching yourself rule response (A) is "You feel your body. Magnificent!"
	The report touching other people rule response (A) is "[the attendant] snaps and says, 'Don't touch the other passengers.'"
	The report touching things rule response (A) is "You touch [the noun]. It feels exactly as you expected."
 The can't pull people rule response (A) is "[the attendant] snaps and says, 'Don't touch the other passengers.'"
	The can't push people rule response (A) is "[the attendant] snaps and says, 'Don't touch the other passengers.'"
	The can't turn people rule response (A) is "[the attendant] snaps and says, 'Don't touch the other passengers.'"
	The innuendo about squeezing people rule response (A) is "Hmmm. Interesting, but you never mix business with pleasure."
	 The block saying yes rule response (A) is "Quite so.".

	The block saying no rule response (A) is "Well, then.".

	The block burning rule response (A) is "You haven't set a fire in a train car in at least a month, and you're not going to start now."
	The block waking up rule response (A) is "You snap out of it, and realize you daydreamed everything. You find yourself in your real body, [if the player is in observation car]in[otherwise]near[end if] an observation car, in the exact same situation you were dreaming of."
	The block thinking rule response (A) is "You've been doing a lot of that recently, and it hasn't helped much."
	The report smelling rule response (A) is "There are numerous odors in the room, mostly coming from your various costumes in the suitcase."
	The report listening rule response (A) is "[if the observation car is toasty]You don't hear anything unexpected. At least the radiator turned off[otherwise]You hear the rattle of the radiator[end if][if the parrot is musical]. Horus is singing pretty loudly, though[end if]."
	The report tasting rule response (A) is "Ever since a close brush with arsenic from a rival, you've avoided tasting random public objects."
	The block cutting rule response (A) is "You have nothing to cut with."
	The can't push unpushable things rule response (A) is "Hmm, perhaps not."

The parser error internal rule response (E) is "[if in darkness]It's too dark to tell if what you typed is here.[otherwise]You look around, but there's nothing by that precise name that you can see.[end if]";

The parser error internal rule response (X) is "[lookaction]";

The parser error internal rule response (N) is "[one of]Your first word had a typo or is one I'm not familiar with. Try a different word.[or]The first word you typed was not recognized.[stopping]"; 

The parser error internal rule response (B) is "Your sentence had too many words; you can try typing just the part where you wanted to ";

The parser error internal rule response (C) is "Your sentence had too many words; you can try typing just the part where you wanted to (go) ";
	
	The report jumping rule response (A) is "You don't want to draw attention to yourself, so you bounce on your feet a bit."
	The block tying rule response (A) is "You have nothing useful to tie with."
	The block drinking rule response (A) is "That's not potable."
	The block saying sorry rule response (A) is "It's quite alright."
	The block swinging rule response (A) is "That's not really how it works."
	The can't rub another person rule response (A) is "Oh! Perhaps not."
	The block buying rule response (A) is "You didn't bring any cash with you, and while you could easily obtain some, that's not your purpose here."
	The block climbing rule response (A) is "Climbing inside a train car has surprisingly little use."
	The block sleeping rule response (A) is "You fall asleep, and begin dreaming a dream that is exactly like reality. You are [if the player is not in observation car]near[otherwise]in[end if] a train car."
	The requested actions require persuasion rule response (A) is "[The noun] pays you no heed.".

	The carry out requested actions rule response (A) is "[The noun] pays you no heed.".

	The can't go that way rule response (A) is "[if the player is in station]The train is to the east. Entering an eastward train by not going east is an interesting but ineffective strategy.[otherwise if the gavinchian rose is not carried by the player]You're not going anywhere until you get that gem![otherwise]A discreet exit to the south would be best.[end if]"
	
	The block giving rule response (A) is "[The second noun] is not interested."

	
The can't take people's possessions rule response (A) is "[if the noun is the grooming kit]Hogg glares at you. 'That's for Horus!' she declaims. 'You're not his groomer!'[otherwise]That'd be difficult to do discreetly, and taking it doesn't serve your ultimate goal at this time.[end if]"

The can't take scenery rule response (A) is "That ought to remain in place right now."

To say lookaction:
	say "You look around.";
	try looking;

The gorilla costume is a costume. The description of the gorilla costume is "A very convincing gorilla suit, purchased, no doubt, at Angels Costumiers on Shaftesbury Avenue. A convincing impersonation is all in the gestures, of which you are a true master. You have every confidence of being able, with a little practice, to pull off a gorilla impression worthy of a Charles Gemora or a Ray 'Crash' Corrigan." The smell of the gorilla costume is "like bananas".

DonningText of the gorilla costume is "This is simply bananas."

The introduction of the gorilla costume is "'Ooh. Ooh.'

She lights up. 'Why, it's Bongo the gorilla! Who'd have thought you'd make your way to the states! Please, make yourself at home,' she says, indicating the car."

The greeting of the gorilla costume is "'Ooh ah, ooh ah ah!'

The attendant peers at you closely. 'Harold?' she asks. She looks a little closer. 'I'm sorry, I thought you were my ex-husband.'"

The familiarity of the gorilla costume is "'Ooh ah, ooh ooh ah?'

The Viscount sighs deeply, puts his magazine on his seat, then walks out of the room. You hear muffled screaming. The Viscount then returns, sits on the chair, grabs the magazine, and begins reading again, ignoring you."

Xyzzying is an action applying to nothing. Understand "xyzzy" as xyzzying.

Cheating is an action applying to nothing. Understand "cheat" as cheating.

CheatFlag is a number that varies. CheatFlag is 0.

Carry out cheating:
	if CheatFlag is 0:
		say "Pffft. You don't have that power. Yet.";
	otherwise:
		end the story finally saying "You won.";

Carry out xyzzying:
	if the gorilla costume is not nowhere:
		now CheatFlag is 1;
		say "Sorry, the gorilla costume is all there is.

Wait, no. Now you can instantly win by typing CHEAT.";
	otherwise:
		say "Check the suitcase.";
		now the gorilla costume is in the suitcase;

Singing is an action applying to nothing. Understand "sing" as singing.

Carry out singing:
	say "You belt out a few lines in a beautiful tenor voice. [The attendant] hushes you[if not in darkness] with a finger on her lips[end if]."

Part 3 - Other Necessary Rules

Chapter 1 - Rulebook changes

Section 1 - Redundancy removal

[The examine containers rule is not listed in any rulebook.]

Chapter 2 - Meta verbs

Abouting is an action out of world. Understand "about" or "credits" or "help" as abouting.

Carry out abouting:
	say "This game is set in the world of the 2018 game Alias 'The Magpie' by JJ Guest. It was written by Mathbrush in fulfillment of a prize given out that year. This game has been tested by Caleb Wilson, Nils Fagerburg, Lance Campbell, Thomas Mack, Mike Russo, Arthur DiBianca, Peter M.J. Gross, Linus Åkesson, Dark Star, Victor Gijsbers, AKheon, Eli Shupe, Mike Sousa, Christopher Merriner, Robb Sherwin and JJ Guest. 

Cover art copyright Mads Weidner.

In this game conversation is carried out by SAYing an available topic. Topics can be found by TALKing TO the character you are interested in, or typing TOPICS or T for short. Each topic can only be spoken to a specific character.

For instance, you can SAY HELLO to say the Hello topic to the parrot. You can RECALL or REMEMBER a topic to remind yourself what happened previously.

For hints on what to do next, type HINT. For a walkthrough, type WALKTHROUGH."

Book 2 - Hints


Hinting is an action out of world. Understand "help" or  "hint" or "hints" as hinting.

Carry out hinting:
	if the player is in Station:
		if Greetings is not TargetGiven:
			say "To proceed, type SAY GREETINGS.";
		otherwise:
			say "Just GO EAST.";
	otherwise:
		say "There are many simultaneous tasks in this game, all involving the other characters. Type HINT HOGG, HINT BIRD, HINT ATTENDANT, or HINT VISCOUNT to get specific hints about that individual. The hints will become more and more specific as you keep getting hints."
	
HoggHinting is an action out of world. Understand "Hint Hogg/cornelia" as HoggHinting.

Carry out HoggHinting:
	if the shades are not drawn:
		say "[one of]Cornelia Hogg will see your shadow if you approach her.[or]But it's too dark to grab the rose when you're in a tunnel.[or]Have you looked at the windows?[or]You need to draw the shades.[or]But the attendant won't let you.[or]You need to be wearing the maintenance uniform to draw the blinds.[or]SKIP. WEAR MAINTENANCE. PULL SHADES.[stopping]";
	otherwise if Cornelia Hogg is thirsty:
		say "[one of]Have you tried taking the rose?[or]Cornelia Hogg is restless because she's thirsty.[or]Her favorite drink is juice.[or]Wait for the server to come in, and grab some juice to give Cornelia.[or]You'll need to be wearing the waiter costume.[or]SKIP. WEAR WAITER. WAIT (until the server is in the room). TAKE JUICE. GIVE JUICE TO HOGG.[stopping]";
	otherwise if the grooming kit is carried by Cornelia Hogg:
		say "[one of]Have you tried taking the rose?[or]You'll need a delicate touch to get the rose.[or]Have you noticed anything that will help you grab the rose?[or]Cornelia Hogg is carrying a pet grooming kit with some tweezers.[or]To get the kit, you'll need to assume an appropriate disguise.[or]SKIP. WEAR PET. SAY INTRODUCTIONS.[stopping]";
	otherwise if the tweezers are not carried by the player:
		say "[one of]You'll need something to grab the Rose with. Cornelia Hogg is sensitive.[or]OPEN KIT. TAKE TWEEZERS.[stopping]";
	otherwise if the player is wearing a stinky costume:
		say "[one of]Have you tried taking the rose?[or]Cornelia thinks you smell bad.[or]Your costume has a distinct odor.[or]One of your costumes has a scent that will particularly delight her.[or]SKIP. WEAR BANKER.[stopping]";
	otherwise if the parrot is not musical:
		say "[one of]Have you tried taking the rose?[or]You're a bit too noisy. You'll need some kind of distraction.[or]Getting Horus to sing could be useful.[or]See the hints for Horus by typing HINT BIRD.[stopping]";
	otherwise if the Viscount is in Observation Car:
		say "The Viscount won't let you grab the Rose. Type HINT VISCOUNT for hints about the Viscount.";
	otherwise if the Gavinchian rose is not carried by the player:
		say "The Rose is yours! Take it!";
	otherwise:
		say "What are you doing? Just GO SOUTH."
		
BeatriceHinting is an action out of world. Understand "HINT ATTENDANT/beatrice" as BeatriceHinting.

Carry out BeatriceHinting:
	say "The attendant does not have any independent puzzles of her own. To stay out of her way, just make sure you're wearing the appropriate costume for all your actions."
	
BirdHinting is an action out of world. Understand "HINT BIRD/parrot/horus" as birdhinting.

Carry out BirdHinting:
	if the parrot is offended:
		say "[one of]Horus is offended. Giving him a cracker should help.[or]GIVE CRACKER TO HORUS.[stopping]";
	otherwise if snack is not carried by the player:
		say "[one of]Have you tried saying Hello?[or]SAY HELLO.[stopping]";
	otherwise if performance is not carried by the player:
		say "[one of]It might be good to indulge Horus in his ideas.[or]SAY SNACK.[stopping]";
	otherwise if music is not carried by the player:
		say "[one of]It might be good to indulge Horus in his ideas.[or]SAY PERFORMANCE.[stopping]";
	otherwise if the parrot is not musical:
		say "[one of]Horus is good for two things, and the most important is: distraction.[or]Before taking the rose, make sure to SAY MUSIC so Horus can cover the noises you make.[stopping]";
	otherwise if the wide hat is worn by the viscount:
		say "[one of]There's one more thing Horus is good for.[or]It involves the Viscount.[or]Have you looked at the Viscount's hat?[or][hathint][stopping]";
	otherwise:
		say "You've done everything you can with Horus."
		
ViscountHinting is an action out of world. Understand "HINT VISCOUNT" as ViscountHinting.

Carry out ViscountHinting:
	if the Fake Beard is worn by Viscount:
		say "[one of]Have you tried looking at the Viscount?[or]The Viscount has a clearly fake beard that needs removing.[or]You need a solvent.[or]Like some strong alcohol.[or]WAIT until the server appears, then TAKE VODKA and POUR VODKA ON BEARD.[stopping]";
	otherwise if the heavy scarf is worn by Viscount:
		say "[one of]Have you tried looking at the Viscount?[or]The Viscount is hiding their true identity with a heavy scarf.[or]It looks awfully hot.[or]Have you heard the radiator hissing?[or]Look at the radiator.[or]You just need to turn the knob to heat things up.[or]Better wear the right costume first.[or]SKIP. WEAR MAINTENANCE. TURN KNOB.[stopping]";
	otherwise if the wide hat is worn by Viscount:
		say "[one of]Have you tried looking at the Viscount?[or]The wide hat is hiding their true identity.[or]It looks a bit like a mouse's nest.[or][hathint][stopping]";
	otherwise:
		say "You've already dealt with the Viscount!";


To say hathint:
	if the grooming kit is carried by Cornelia Hogg:
		say "[one of]Have you seen a mouse anywhere?[or]Cornelia Hogg is carrying a pet grooming kit with a mouse.[or]To get the kit, you'll need to assume an appropriate disguise.[or]SKIP. WEAR PET. SAY INTRODUCTIONS.[stopping]";
	otherwise:
		say "[one of]Take the mouse out of the grooming kit.[or]Horus seems eager to attack, doesn't he?[or]PUT MOUSE ON HAT. SAY DESTROY.[stopping]";

Walkthroughing is an action out of world. Understand "walkthrough" as walkthroughing.

Carry out walkthroughing:
	say "east / say greetings / e

 z  / z / z / take vodka / take juice / pour vodka on beard

(note that you can't take the vodka and juice unless the waiter is present)

skip / wear groomer / z  / z / say Introductions / x kit / open kit /  take mouse / throw mouse at hat / say destroy to horus

skip / wear maintenance / z / x radiator / turn knob

skip / wear waiter / give juice to hogg

skip / wear maintenance / z / pull blinds

get tweezers

skip / wear banker / z

x parrot / say hello to horus / say snack / say performance / say music

get rose/s."

Part 4 - Testing

BoxTesting is an action applying to nothing. Understand "boxize" as boxtesting.

Carry out boxtesting:
	repeat with current running through containers:
		say "[current][line break]";
		
Test me with "test intro/ test beard / test mouse / test radiator / test thirst / test sight / test touch/ test smell / test horus / test gem"

Test intro with "east / say greetings / e "

Test beard with " z  / z / z / z / take vodka / take juice / pour vodka on beard"

Test mouse with "skip / wear groomer / z  / z / say Introductions / x kit / open kit /  take mouse / throw mouse at hat / say destroy to horus"

Test radiator with "skip / wear maintenance / z / x radiator / turn knob"

Test thirst with "skip / wear waiter / give juice to hogg"

Test sight with "skip / wear maintenance / z / pull blinds"

Test touch with "get tweezers"

Test smell with "skip / wear banker / z"

Test horus with "x parrot / say hello to horus / say snack / say performance / say music"

Test gem with "get rose/ take feather / drop feather/s"

Quipchecking is an action out of world. Understand "quips" as quipchecking.

Carry out quipchecking:
	repeat with current running through quips:
		say "Summary of [current]: [targetsummary of current]";
		say "[line break]";

Book 3 - Design Notes and Amusing Text

Understand "give [crackers] to [someone]" as giving it to.

Rule for amusing a victorious player: 
	say "Have you tried...

...poking the parrot?

...spilling a liquid on people besides the Viscount?

...feeding Horus every cracker in the box? (there are 20 crackers total)

...mixing the drinks?

...mixing them again?

...engaging in conversation with the Viscount and/or Beatrice while wearing different costumes?

...XYZZY?

...XYZZY again?

...giving different drinks to different people?"

Plughing is an action applying to nothing. Understand "plugh" as plughing.

Carry out plughing:
	say "Well, you are certainly thorough. Message the author with your name and I'll put it in this space."

[Add responses to each costume for every quip]